Change all data markers (excel chart) to triangles in one command

#1 11-23-2005, 07:55 PM

There must be some command which tells a new chart to randomize colors and
symbols- this can look junky. I would llike to find a way to change all
symbols simultaneouly to various shapes until I find what makes the chart
most read-able.
thankyou

#2 11-26-2005, 02:10 PM

It's not a single command. You need to loop through the series in a chart
and apply colors and symbols as you see fit. This procedure cycles among the
marker shapes in a line or XY chart:

Sub RotateMarkers()
Dim srs As Series
Dim NewMarker As Long

Select Case ActiveChart.SeriesCollection(1).MarkerStyle
Case xlMarkerStyleCircle
NewMarker = xlMarkerStyleDiamond
Case xlMarkerStyleDiamond
NewMarker = xlMarkerStyleSquare
Case xlMarkerStyleSquare
NewMarker = xlMarkerStyleTriangle
Case xlMarkerStyleTriangle
NewMarker = xlMarkerStylePlus
Case xlMarkerStylePlus
NewMarker = xlMarkerStyleStar
Case xlMarkerStyleStar
NewMarker = xlMarkerStyleX
Case xlMarkerStyleX
NewMarker = xlMarkerStyleCircle
Case Else
NewMarker = xlMarkerStyleCircle
End Select

For Each srs In ActiveChart.SeriesCollection
srs.MarkerStyle = NewMarker
Next
End Sub

- Jon
-------
Jon Peltier, Microsoft Excel MVP
Peltier Technical Services
Tutorials and Custom Solutions
http://PeltierTech.com/
_______

"jawn" <jawn@discussions.microsoft.com> wrote in message
news:475E9A1F-E77E-4AB9-BD2F-52C32A27DF47@microsoft.com...
>
> There must be some command which tells a new chart to randomize colors and
> symbols- this can look junky. I would llike to find a way to change all
> symbols simultaneouly to various shapes until I find what makes the chart
> most read-able.
> thankyou

Thread Tools	Search this Thread
Show Printable Version Email this Page	Search this Thread: Advanced Search
Display Modes
Linear Mode Switch to Hybrid Mode Switch to Threaded Mode

Currently Active Users Viewing This Thread: 1 (0 members and 1 guests)