Extracting a Substring Between Second and Third Delimiters

In column A of an Excel spreadsheet I have a series of file-path strings always in this format: C:\FolderNm1\FolderNm2\FileNm

I need a formula that will extract the FolderNm2 substring in to column B

The string will always be between the 2nd and 3rd delimiter ' \ ' , but will vary in length and characters; in may also contain spaces and other special characters

I did search the forums and didn't find an example I could follow and modify to my needs (I am an Excel novice - or whatever is less than that)

Any assistance is greatly appreciated and thank you in adavance

MG

=MID(B1,FIND("\",B1,FIND("\",B1)+1)+1,FIND("\",B1,FIND("\",B1,FIND("\",B1)+1)+1)-(FIND("\",B1,FIND("\",B1)+1)+1))

Formula Logic:

=find("\",B1) - location of first "\"

=find("\",b1,find("\",B1)+1)) - location of second "\"

=find("\",b1,find("\",b1,find("\",B1)+1)) - location of third "\"

=MID(what text,starting at what character,go for how many characters)

=MID(B1,location of second "\" + 1,location of third "\" - (location of second "\" +1))

=MID(B1,FIND("\",B1,FIND("\",B1)+1)+1,FIND("\",B1,FIND("\",B1,FIND("\",B1)+1)+1)-(FIND("\",B1,FIND("\",B1)+1)+1))

=MID(B1,12+1,22-(12+1))

=MID(B1,13th character, go on for 9 characters)

Originally Posted by tony h

Robert's post is much simpler than the one I had intended

For reals..