Thread: looping in the find command

I am trying to provide a search string and then loop round searching for this search string until the beginning find cell is found again however I am having problems making my code work - here it is:

Sub searchname()
'
' searchname Macro
'
' Keyboard Shortcut: Ctrl+Shift+C
'

' An input box used to place a value into a variable
    Dim strMessage As String
    Dim actadd2 As String
    
    strMessage = InputBox("Please enter what you wish to search for:")
    strMessage = strMessage
    MsgBox "This is what you entered " & strMessage
    
    
        Cells.Find(What:=strMessage, After:=ActiveCell, LookIn:=xlFormulas, _
        LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
        MatchCase:=False, SearchFormat:=False).Activate
    
    'Cells.FindNext(After:=ActiveCell).Activate
    
    If Not ActiveCell Is Nothing Then
    MsgBox (ActiveCell)
    actadd2 = ActiveCell.Address
    MsgBox (actadd2)
    Do
             
         Cells.FindNext(After:=ActiveCell).Activate

    Loop While Not ActiveCell Is Nothing And ActiveCell.Address <> actadd2
    End If

End Sub

Many Thanks

Hello jmgriffin101,

I made the necessary changes for you. It will stop now when you loop back to the start of the search.

Sub searchname()
'
' searchname Macro
'
' Keyboard Shortcut: Ctrl+Shift+C
'

' An input box used to place a value into a variable
    Dim FirstAddx As String
    Dim strMessage As String
    Dim actadd2 As String
    Dim Result As Range
    
    strMessage = InputBox("Please enter what you wish to search for:")
    strMessage = strMessage
    MsgBox "This is what you entered " & strMessage
    
    Set Result = Cells.Find(What:=strMessage, After:=[A1], _
                 LookIn:=xlFormulas, LookAt:=xlWhole, SearchOrder:=xlByRows, _
                 SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False)
    
    If Not Result Is Nothing Then
       FirstAddx = Result.Address
       MsgBox Result.Value
         Do
           Result.Activate
           MsgBox Result.Value
           Set Result = Cells.FindNext(Result)
         Loop While Not Result Is Nothing And Result.Address <> FirstAddx
    End If

End Sub