Thread: Verify existence of a custom add-in

Hello... do any of you experts know if there's a way I can verify that a custom add-in is active?

My company uses an add-in to allow end users to construct several types of API calls. My program depends on that add-in to be installed. I'd like to try to detect the add-in and halt the program if it's not there.

Thanks for any help!

Good afternoon JP Romano

Originally Posted by JP Romano

do any of you know if there's a way I can verify that a custom add-in is active?

The code below will return a True / False answer :

Code:

MsgBox AddIns("My Add-In").Installed

HTH

DominicB

This pair of functions may help:

Code:

Function AddinIsInstalled(ByVal sName As String) As Boolean
    ' Returns returns True if add-in is installed
    Dim oAddIn As AddIn
    
    sName = UCase(sName)
    For Each oAddIn In Application.AddIns
        If UCase(oAddIn.Name) = sName Then
            AddinIsInstalled = True
            Exit For
        End If
    Next oAddIn
End Function

Function InstallAddIn(ByVal sPath As String, sName As String) As Boolean
    ' Installs an add-in, returns True if successful.
    Dim oAddIn As AddIn
    
    If Right(sPath, 1) <> "\" Then sPath = sPath & "\"
    If AddinIsInstalled(sName) Then Application.AddIns(sName).Installed = False

    On Error Resume Next
    Set oAddIn = Application.AddIns.Add(sPath & sName)
    oAddIn.Installed = True
    InstallAddIn = Err.Number = 0
    Err.Clear
End Function

Example usage:

Code:

InstallAddIn "C:\myPath", "myAddIn.xla"