Thread: Move rows to new sheet on condition

Given the lack of details and a sample workbook, perhaps this can be a start for you.

Option Explicit

Sub MoveRows()

    Dim lastrow As Long
    
    lastrow = Sheet2.Cells(Rows.Count, 1).End(xlUp).Row + 1
    
    Application.ScreenUpdating = False
    
    With Sheet1
    
        .Range("A1").CurrentRegion.AutoFilter Field:=2, Criteria1:="=N", Operator:=xlAnd
        .Range("a1").CurrentRegion.Offset(1, 0).SpecialCells(xlCellTypeVisible).Copy Sheet2.Range("A" & lastrow)
        .Range("A1").CurrentRegion.Offset(1, 0).SpecialCells(xlCellTypeVisible).EntireRow.Delete
        .AutoFilterMode = False
    
    End With
    Application.CutCopyMode = False
    Application.ScreenUpdating = True

End Sub

See attached.

The code I gave is just a basic approach based on the description in your thread and is, therefore, not tailored to your specific workbook and would have to be modified.

It would be best if you uploaded a sample workbook that both duplicates the exact structure of your real workbook and contains some data (non-sensitive). We could then tailore the code to the exact needs of your workbook.

here is the attached workbook example, hope this works.

thanking you in advance.

ammended

Please re-upload a new worbook that contains representative data so we can get the right solution and eliminate questions. You can edit your previous post to remove the attachement and then upload the new workbook in the same post then reply to this post to let us know.

Option Explicit
Sub Move_N_Rows()

    Dim lrowSh1 As Long, lcolSh1 As Long, lrowSh2 As Long
    
    lrowSh1 = Sheet1.Cells(Rows.Count, 2).End(xlUp).Row
    lrowSh2 = Sheet2.Cells(Rows.Count, 2).End(xlUp).Row + 1
    lcolSh1 = Sheet1.Cells(6, Columns.Count).End(xlToLeft).Column
    
    If lrowSh2 < 3 Then lrowSh2 = 3 'account for header row
    
    Application.ScreenUpdating = False
    
    With Sheet1
        If .AutoFilterMode = True Then .AutoFilterMode = False
        .Range("B6", Cells(lrowSh1, lcolSh1)).AutoFilter field:=1, Criteria1:="=N", Operator:=xlAnd
        .Range("B6", Cells(lrowSh1 - 1, lcolSh1)).Offset(1, 0).SpecialCells(xlCellTypeVisible).Copy Sheet2.Range("B" & lrowSh2)
        .Range("B6", Cells(lrowSh1 - 1, lcolSh1)).Offset(1, 0).SpecialCells(xlCellTypeVisible).EntireRow.Delete
        .AutoFilterMode = False
    End With
    
    Application.ScreenUpdating = True

End Sub

See attached.