Thread: Default Track all the changes of all the columns in respective rows of column A

How about capturing the changes and populating a cell comment box?

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim sUser As String, sComment As String, lCol As Long
    
    If Target.Cells.Count > 1 Then Exit Sub
    
    Select Case Target.Column
        Case 2: lCol = 27
        Case 7: lCol = 28
    End Select
    
    If Target.Column = 2 Or Target.Column = 7 Then
        sUser = Environ("Username")
        sComment = vbCrLf & Date & ": Changed by " & sUser & " from " & Cells(Target.Row, lCol) & " to " & Target.Value & Chr(10)
        With Target
            If Not .Comment Is Nothing Then
                .Comment.Text Text:=.Comment.Text & sComment
            Else
                .AddComment Text:=sComment
            End If
            .Comment.Shape.TextFrame.AutoSize = True
        End With
    End If

End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    If Target.Cells.Count > 1 Then Exit Sub
    
    Application.ScreenUpdating = False
    Select Case Target.Column
        Case 2
            Range("AA" & Target.Row) = Target.Value
            
        Case 7
            Range("AB" & Target.Row) = Target.Value
    
    End Select
    
    Application.ScreenUpdating = True

End Sub