Thread: Userforms: Textbox Searches

Hello Everyone,

I've been working the past little while to create a Excel Acronym Search Engine. Everyone thus far has been a great help. I'm almost done. I'm currently combating one more issue. in the sheet labled "Acronym Search Engine" , of the attached workbook, I have created multiple text boxes. These text boxes display the search results from whats typed into the "Acronym" Text box. Now I want to deal with having multiple acronyms, I want them to display in the subsequent text boxes. I've been playing with the "SearchNext" and "SearchPrevious" but with now luck.

Does anyway have any idea how I could display multiple definitions if they did exists?

I've attached a workbook for clarification.

Thank you so much everyone

how about this.

Private Sub TextBox1_Change()

    Dim lngIndex As Long
    Dim strAcronym As String
    Dim rngFind As Range
    Dim strFirstAddress As String
    Dim strName As String
    Const NTEXTBOXES = 25
    
'    On Error Resume Next
'Empty Text Boxes'
    For lngIndex = 2 To NTEXTBOXES
        Me.Shapes("Textbox" & lngIndex).OLEFormat.Object.Object.Text = ""
    Next

    lngIndex = 2
    strAcronym = Me.Shapes("Textbox1").OLEFormat.Object.Object.Text
    If Len(strAcronym) > 0 Then
        strAcronym = strAcronym & "*"
        With Worksheets("Acronym Database").Range("A1").CurrentRegion.Columns(1)
            Set rngFind = .Find(What:=strAcronym)
            If Not rngFind Is Nothing Then
                strFirstAddress = rngFind.Address
                Do
                    Me.Shapes("Textbox" & lngIndex).OLEFormat.Object.Object.Text = rngFind.Offset(0, 1).Value
                    Me.Shapes("Textbox" & lngIndex + 1).OLEFormat.Object.Object.Text = rngFind.Offset(0, 2).Value
                    Me.Shapes("Textbox" & lngIndex + 2).OLEFormat.Object.Object.Text = rngFind.Offset(0, 3).Value
                    
                    lngIndex = lngIndex + 3
                    If lngIndex > NTEXTBOXES Then Exit Do
                    Set rngFind = .FindNext(rngFind)
                Loop While Not rngFind Is Nothing And rngFind.Address <> strFirstAddress
            End If
        End With
    End If
End Sub

If you add the LookAt argument you can restrict it to a match with string begining with the letters. So AF would return these 3, AFC,AFD,AFE

            Set rngFind = .Find(What:=strAcronym, Lookat:=xlWhole)

If you only what exact matches then also alter this line by commenting out the wildcard search

        strAcronym = strAcronym '& "*"