Thread: Userform, finding referenced cell by category and date and adding value to worksheet.

Your file won't open for me, can you try saving the file above in Excel 97-2003 format .xls?

This is how I would do that. you seem to have some variations on the individual sheets and the titles of columns and such. There's no need to worry about that, your form can grab the appropriate titles across row 5 in each sheet, it won't matter if they're the same from sheet to sheet. These macros will get the column categories and the dates from the "activesheet", the enter the values into the table accurately as you make entries.

If you select the same date/category a second time, it will add the values together.

Private Sub cmdAdd_Click()
Dim iRow As Long, iCol As Long

If cmbDate = "" Then
    MsgBox "please select a date"
    cmbDate.SetFocus
    Exit Sub
End If
If cmbCat = "" Then
    MsgBox "please select a category"
    cmbCat.SetFocus
    Exit Sub
End If
If txtAmount = "" Then
    MsgBox "please enter then amount"
    txtAmount.SetFocus
    Exit Sub
End If

With ActiveSheet
    iRow = .Range("A:A").Find(cmbDate.Value, LookIn:=xlValues, LookAt:=xlWhole).Row
    iCol = .Range("5:5").Find(cmbCat.Value, LookIn:=xlValues, LookAt:=xlWhole).Column
    .Cells(iRow, iCol) = .Cells(iRow, iCol) + txtAmount
End With

'clear the data
    cmbDate.Value = ""
    cmbCat.Value = ""
    txtAmount.Value = ""
    cmbDate.SetFocus

End Sub

Private Sub cmdDone_Click()
    Unload Me
End Sub

Private Sub UserForm_Initialize()
Dim cItem As Range

Dim ws As Worksheet

Set ws = ActiveSheet
For Each cItem In ws.Range("5:5").SpecialCells(xlConstants).Offset(, 1)
    With Me.cmbCat
        If cItem <> "" And cItem <> "Total" Then .AddItem cItem.Value
    End With
Next cItem

For Each cItem In ws.Range("A:A").SpecialCells(xlConstants, xlNumbers)
    With Me.cmbDate
        .AddItem cItem.Value
    End With
Next cItem

End Sub

If that takes care of your need, please click EDIT in your original post, click GO ADVANCED and set the PREFIX box to SOLVED.