Thread: Macro help to copy row from one spreadsheet to another

sfoxbox,

Based on your latest request, and your Private Message, try the following.


Please TEST this FIRST in a COPY of your workbook (always make a backup copy before trying new code, you never know what you might lose).

Option Explicit
Sub GetIncompleteV4()
' stanleydgromjr, 01/24/2012
' http://www.excelforum.com/excel-programming/809567-macro-help-to-copy-row-from-one-spreadsheet-to-another.html
Dim wF As Worksheet, wP As Worksheet, wE As Worksheet
Dim c As Range, firstaddress As String, lr As Long, nr As Long
Application.ScreenUpdating = False
Set wF = Worksheets("Full Report")
Set wP = Worksheets("Prioritized Report")
Set wE = Worksheets("Executive Summary")
wF.Range("A1:J7").Copy wP.Range("A1")
wF.Range("A1:E3").Copy wE.Range("A1")
lr = wP.Cells(Rows.Count, "D").End(xlUp).Row
If lr > 7 Then wP.Range("A8:J" & lr).Clear
nr = 8
With wF.Columns(4)
  Set c = .Find("No", LookIn:=xlValues, LookAt:=xlWhole)
  If Not c Is Nothing Then
    firstaddress = c.Address
    Do
      wF.Rows(c.Row).Copy wP.Range("A" & nr)
      nr = wP.Range("D" & Rows.Count).End(xlUp).Offset(1).Row
      Set c = .FindNext(c)
    Loop While Not c Is Nothing And c.Address <> firstaddress
  End If
End With
wP.Activate
Application.ScreenUpdating = True
End Sub

Before you use the macro with Excel 2007 or newer, save your workbook, Save As, a macro enabled workbook with the file extension .xlsm


Then run the GetIncompleteV4 macro.

sfoxbox,

Thanks for the feedback.

You are very welcome. Glad I could help.

Come back anytime.