Thread: Sorting table of data into order

What (if anything) determines who should appear first in the case of duplicate points - eg Ronald & Mildred - given these are tied is the order then determined by other point values ?

Hmm... alphabetical actually makes things a little messy...

What you could do - based on your sample file and assuming XL2007:

Code:

V3: =1+COUNTIFS($O$3:O$9,$O3,$N$3:$N$9,"<"&$N3)
copied down

then for your left table

Code:

C3: =INDEX($N$3:$N$9,MATCH(1,INDEX(($O$3:$O$9=$D3)*($V$3:$V$9=COUNTIF($D$3:$D3,$D3)),0),0))
copied down to C9

D3:
=LARGE($O$3:$O$9,$B3)
copied down to D9

E3:
=INDEX(P$3:P$9,MATCH($C3,$N$3:$N$9,0))
copied across to J3
copied down to E9:J9

Does that help ?

(there will be better methods I'm sure...)

Actually, in hindsight, if you opt to use helper formulae in column V you could just use:

Code:

V3:
=1+COUNTIF($O$3:$O$9,">"&$O3)+COUNTIFS($O$3:$O$9,$O3,$N$3:$N$9,"<"&$N3)
copied down to V9

Then

Code:

C3: 
=INDEX(N$3:N$9,MATCH($B3,$V$3:$V$9,0))
applied to entire matrix C3:J9