Thread: Format text in e-mail body

Hi

I want to be able to send a basic e-mail with the body text containing certain words in bold and underlined.

I have tried to force Outlook 2003 to convert the message to Rich Text or HTML format with no success.

Please can anyone assist or even tell me if it is possible?

I have the following code:

Code:

Sub Mail_small_Text_Outlook()
'Working in Office 2000-2007
    Dim OutApp As Object
    Dim OutMail As Object
    Dim strbody As String

    Set OutApp = CreateObject("Outlook.Application")
    OutApp.Session.Logon
    Set OutMail = OutApp.CreateItem(0)

    strbody = "Hi Roxanne" & vbNewLine & vbNewLine & _
              "Sorry for all the e-mails but " & _
              "I am testing something for Martin." & vbNewLine & vbNewLine & _
              "Thank you" & vbNewLine & vbNewLine & _
              "Tom"

    On Error Resume Next
    With OutMail
        .To = "test@test.com"
        .CC = ""
        .BCC = ""
        .Subject = "Test for Tom"
        .Body = strbody
        'You can add a file like this
        '.Attachments.Add ("c:\MailBody.txt")
        .Send   'or use .Display
    End With
    On Error GoTo 0

    Set OutMail = Nothing
    Set OutApp = Nothing
    
End Sub

Use HTMLBody and then use standard HTML mark-up, eg:

Code:

Sub Mail_small_Text_Outlook()
'Working in Office 2000-2007
    Dim OutApp As Object
    Dim OutMail As Object
    Dim strbody As String

    Set OutApp = CreateObject("Outlook.Application")
    OutApp.Session.Logon
    Set OutMail = OutApp.CreateItem(0)

    strbody = "Hi <b>Roxanne</b>" & vbNewLine & vbNewLine & _
              "Sorry for all the e-mails but " & _
              "I am testing <u>something</u> for <i><font color=red>Martin</font></i>." & vbNewLine & vbNewLine & _
              "Thank you" & vbNewLine & vbNewLine & _
              "Tom"

    On Error Resume Next
    With OutMail
        .To = "test@test.com"
        .CC = ""
        .BCC = ""
        .Subject = "Test for Tom"
        .HTMLBody = strbody
        'You can add a file like this
        '.Attachments.Add ("c:\MailBody.txt")
        .Send   'or use .Display
    End With
    On Error GoTo 0

    Set OutMail = Nothing
    Set OutApp = Nothing
    
End Sub

Re: CSS - no idea... I wouldn't have thought so, no.

Re: VBA - simply code the HTML mark up into the string as illustrated.