Disallow File Save if No Input in Cells?

[Dan Raab]

Is there any way to require data entry into cells such that the save/save as functions can be disabled until the data is entered?

Thanks,

Dan

[Chip Pearson]

You can use the BeforeSave event procedure to do this. In the
ThisWorkbook code module, use the following code:

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel
As Boolean)
If Worksheets("Sheet1").Range("A1") = "" Then
Cancel = True
End If
End Sub


--
Cordially,
Chip Pearson
Microsoft MVP - Excel
Pearson Software Consulting, LLC
www.cpearson.com



"Dan Raab" <[email protected]>
wrote in message
news:[email protected]...
>
> Is there any way to require data entry into cells such that the
> save/save as functions can be disabled until the data is
> entered?
>
> Thanks,
>
> Dan
>
>
> --
> Dan Raab
> ------------------------------------------------------------------------
> Dan Raab's Profile:
> http://www.excelforum.com/member.php...o&userid=29414
> View this thread:
> http://www.excelforum.com/showthread...hreadid=499474
>

[Dave Peterson]

Maybe....

Saved from a previous post:

Option Explicit
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)

Dim myRng As Range
Dim myEmptyRng As Range
Dim myCell As Range

Set myRng = Me.Worksheets("Form").Range("a1,b9,c12,d13")

If Application.CountA(myRng) > 0 _
And Application.CountA(myRng) < myRng.Cells.Count Then
Cancel = True
For Each myCell In myRng.Cells
If IsEmpty(myCell) Then
If myEmptyRng Is Nothing Then
Set myEmptyRng = myCell
Else
Set myEmptyRng = Union(myEmptyRng, myCell)
End If
End If
Next myCell
MsgBox myEmptyRng.Address(0, 0) & " must have valid data!"
End If
End Sub

If all the cells are empty, you can still save (nice for changing the master).
But there are other techniques if you don't want to allow all empty cells.

this code goes behind the ThisWorkbook module.

If you're new to macros, you may want to read David McRitchie's intro at:
http://www.mvps.org/dmcritchie/excel/getstarted.htm



Dan Raab wrote:
>
> Is there any way to require data entry into cells such that the
> save/save as functions can be disabled until the data is entered?
>
> Thanks,
>
> Dan
>
> --
> Dan Raab
> ------------------------------------------------------------------------
> Dan Raab's Profile: http://www.excelforum.com/member.php...o&userid=29414
> View this thread: http://www.excelforum.com/showthread...hreadid=499474

--

Dave Peterson