Number of "y", "n" from report for each employee

The KISS principal is still something that often applies, and I believe this is 1 of those times. Why complicate things with PT's and slicers, when a few relatively simple formulas will (I think) give you wnat you want?

	C	D	E
22	Employee	Y	N
23	andres.ocampo	25	4
24	kristopher.brunne	14	3
25	raphael.gauvin	11	2
26	joseph.senga	22	4
27	simon.balti	40	5
28	janick.bergeron	13	2
29	enzo.emanuele	13	0
30	andre.jolin	22	4
31	patrick.tremblay2	9	3
32	gabriel.hebert	14	2
33	gabriel.laprise	10	3

C23=IFERROR(INDEX($C$3:$C$18,MATCH(0,INDEX(COUNTIF($C$22:C22,$C$3:$C$18),),0)),"")
copied down
This will generate a unique list of names
D23=IF(C23="","",SUMPRODUCT(--($C$3:$C$18=$C23)*($I$3:$AG$18=D$22)))
copied down and across
This will count the Y and N for each name

Greeting, this is exactly what i am looking for !

Only one thing ... not quite sure where to enter this, could i have more precise information if its nothing to much, i googled how to but was not able to phrase correctly i guess.

Here the sheet and the 'program' i have been working on, also i am open to feedback/modification that could make this whole thing ive been working on for more than a month (was learning in the same time) look better and work better, there is much for me on the line, and i invested a lot of time onto it, its just the pivot thing i cant figure out ... what a shame ! haha

Sorry for the delay in responding

I see you got it to work, all you needed to do was enter the formula in a cell where you wanted the answers to show, then just copy/paste it down as far as you needed. Also, I set the formula up so that after you have done the "Y", all you need is copy the formulas across to the next column to get the "N"

If you get answers that you did not expect, just change the formatting to General (thats what I had to do, seems most of your cells are formatted as Date).

To put this on another sheet, 1 easy way is to just cut/paste the table to a new sheet, it should adjust the formulas for you.

Or just add the sheet name into the formula...
=IFERROR(INDEX($C$3:$C$18,MATCH(0,INDEX(COUNTIF($C$22:C22,$C$3:$C$18),),0)),"")
becomes
=IFERROR(INDEX(Database1!$C$3:$C$18,MATCH(0,INDEX(COUNTIF($A$1:A1,Database1!$C$3:$C$18),),0)),"")

=IF(C23="","",SUMPRODUCT(--($C$3:$C$18=$C23)*($I$3:$AG$18=D$22)))
becomes
=IF(A2="","",SUMPRODUCT(--(Database1!$C$3:$C$18=$A2)*(Database1!$I$3:$AG$18=B$1)))

Let me know if you have any problems?