Extract text 2 last string

[Jhon Mustofa]

hi all,

i need someone could help me, how to extract string 2 last string, further detail check this below ;

description-------------------------------------desired result------
Our nation's immigration system is broken---------is broken---------
Legal immigration should be simple and efficient----and efficient-------
The President’s proposal is designed----------------is designed--------

with excel formula how to figure it out? do not vba...

thanks in advance.......

john m

[XOR LX]

Hi,

=TRIM(RIGHT(SUBSTITUTE(A1," ",REPT(" ",255)),510))

Regards

[azumi]

Maybe:
=MID(A1;FIND("*";SUBSTITUTE(A1;" ";"*";LEN(A1)-LEN(SUBSTITUTE(A1;" ";""))-1))+1;255)

[Tony Valko]

Try this...

Data Range

	A	B
1	description	desired result
2	Our nation's immigration system is broken	is broken
3	Legal immigration should be simple and efficient	and efficient
4	The President’s proposal is designed	is designed

This formula entered in B2 and copied down:

=MID(" "&A2,FIND("^",SUBSTITUTE(" "&A2," ","^",LEN(" "&A2)
-LEN(SUBSTITUTE(" "&A2," ",""))-1))+1,255)

There must be at least 2 words in the cell or you'll get an error.

[RudiS]

Hi,

If your list starts in cell A1, then enter this formula into cell B1

=IFERROR(RIGHT(A1,LEN(A1)-FIND(CHAR(8),SUBSTITUTE(A1," ",CHAR(8),(LEN(A1)-LEN(SUBSTITUTE(A1," ",""))-1)))),A1)

[Jhon Mustofa]

hi guys, awesome answer...

many thanks...)

[sktneer]

One more still to come.......
You may also try this........

Please Login or Register  to view this content.

[Jhon Mustofa]

hi sktneer, thanks for your reply...
it's worked too...

[sktneer]

Glad to know that. Thanks for the feedback.

[Tony Valko]

You're welcome. We appreciate the feedback!

If I had to pick a favorite it would be from XOR in post #2.

[XOR LX]

You're welcome. We appreciate the feedback!

If I had to pick a favorite it would be from XOR in post #2.

Cheers!