transpose values into one row

Unfilter.
Remove the extraneous examples leaving the raw data.
In C2, then copied across and down:

=TRIM(RIGHT(SUBSTITUTE(INDEX($B$1:$B$500, MATCH($A2&"*"&C$1&"*", INDEX($A$1:$A$500&$B$1:$B$500, 0), 0)), " ", REPT(" ", 50)), 50))

Perhaps a cut and paste error?

This is several formulas merged into one.

An INDEX() is created merging the values from column C and column B:
INDEX($A$1:$A$500&$B$1:$B$500, 0)
This creates an array with values in it that look like this:
151206BI prio: 1
151206BI impact: 3
etc...

Next we index column B, then match using the value in column A+wildcards+the label in C1+wildcards to the array we created above.
INDEX($B$1:$B$500, MATCH($A2&"*"&C$1&"*", INDEX($A$1:$A$500&$B$1:$B$500, 0), 0))

Used in C2, that brings back the value from B3 as the match. Now we want just the last word in that string. First we substitute all the spaces in that string with 50 spaces.
SUBSTITUTE(INDEX($B$1:$B$500, MATCH($A2&"*"&C$1&"*", INDEX($A$1:$A$500&$B$1:$B$500, 0), 0)), " ", REPT(" ", 50))

Then we use the RIGHT() function to just grab the last 50 characters. This gives us the last word only plus some of the spaces we added.
RIGHT(SUBSTITUTE(INDEX($B$1:$B$500, MATCH($A2&"*"&C$1&"*", INDEX($A$1:$A$500&$B$1:$B$500, 0), 0)), " ", REPT(" ", 50)), 50)

Lastly, we use the TRIM function to strip out any of those extra spaces.
=TRIM(RIGHT(SUBSTITUTE(INDEX($B$1:$B$500, MATCH($A2&"*"&C$1&"*", INDEX($A$1:$A$500&$B$1:$B$500, 0), 0)), " ", REPT(" ", 50)), 50))


When that formula is copied to the right, it changes from looking for 151206*prio* to looking for 151206*impact*, this finding B4, and from there going through the same final steps to strip out the last word only.

I didn't download your file.

As far as the general formula error...

You may need to replace the commas with semi-colons.

Glad it's working. My apologies, I never remember to look at the region people are asking from.