Count number of times a specific date happens between two dates

e3 Start
e4 end
d6: date

=IF(DAY(E3)>=D6,IF(DAY(E4)>=D6,DATEDIF(E3,E4,"m")+2,DATEDIF(E3,E4,"m")+1),DATEDIF(E3,E4,"m")

Hi, and welcome to the forum.

=DATEDIF(start_date,end_date,"m")+1

I did this with a helper column (B)...

	A	B	C
1	5/15/2013	12/10/2013
2	4/15/2013	15	7
3	4/16/2013	16
4	5/15/2013	15
5	5/16/2013	16
6	6/15/2013	15
7	6/16/2013	16
8	7/15/2013	15
9	7/16/2013	16
10	8/15/2013	15
11	8/16/2013	16
12	9/15/2013	15
13	9/16/2013	16
14	10/15/2013	15
15	10/16/2013	16
16	11/15/2013	15
17	11/16/2013	16
18	12/15/2013	15
19	12/16/2013	16

B2=DAY(A2)
C2=COUNTIFS($A$2:$A$19,">="&$A$1,$A$2:$A$19,"<="&$B$1,$B$2:$B$19,15)
both copied down

Originally Posted by daffodil11

=IF(DAY(E3)>=D6,IF(DAY(E4)>=D6,DATEDIF(E3,E4,"m")+2,DATEDIF(E3,E4,"m")+1),DATEDIF(E3,E4,"m")

I see the logic that you're aiming for but I don't think this works in all cases, e.g. 10th July to 25th September in the same year includes 3 "15ths" but your formula returns 2

Using a similar logic and with start date in A2, end date in B2 and day to count in C2 (15 in the example) you can use this formula which should work in all cases assuming the day to count is one that occurs every month (i.e. <= 28)

=DATEDIF(A2-DAY(A2)+1,B2,"m")+1-(DAY(A2)>C2)-(DAY(B2)<C2)

....or for a completely different approach but same result

=SUMPRODUCT(--(DAY(ROW(INDIRECT(A2&":"&B2)))=C2))

That latter formula can also be used to give an accurate count of days that don't occur every month, e.g. 29, 30 or 31