Adding up every other cell in a column

[backinblack]

I have been trying to add up every other cell in a column with no luck. I know you can do it this way =sum(A1+C1,E1,G1) etc.. but that will take awhile plus I believe it is limited at how many you can put in it. I have tried a MOD version but I couldn't get that to work. Anyone know how to do that? Thanks

[JieJenn]

Enter the formula with Ctrl + Shift + Enter keys together since it is an array formula

=SUM(IF(MOD(ROW(A1:A11)/2,1),A1:A11,0))

[daffodil11]

The MOD method is generally accepted as the best way.

=SUM(IF(MOD(COLUMN($A$1:$O$1),2)=1,$A$1:$O$1,0))

Are you sure you're entering the formula as an array?

With the cursor in the cell, hold Ctrl+Shift and hit Enter. This will put braces in the formula.

[backinblack]

I'm not very familiar with MOD's so I must be missing some thing. This is what I got. Trying to add up B4, D4, F4, etc.. But it is not working.

excel.JPG

[daffodil11]

Neither of your formulas are entered as Arrays.

...confirmed by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. You will know the array is active when you see curly braces { } appear around your formula. If you do not CTRL+SHIFT+ENTER you will get an error or a clearly incorrect answer. Press F2 on that cell and try again.

[Ace_XL]

Try this regular formula

=SUMPRODUCT(A4:P4*(MOD(COLUMN(A4:P4),2)=MOD(COLUMN($B4),2)))

[backinblack]

Ok got it to work. Found out that it will not work in merged cells. I had 2 cells merged together and it did not like that.

Thanks for all the help everyone!

[Haseeb Avarakkan]

Hello,

Looks like you are totaling "Equip." column. SO you can simply use SUMIF,

=SUMIF(6:6,"Equip*",4:4)

6;6 is sixth row, 4:4 is fourth row.