If and choose formulas combined?

[corduroy82]

Hello,
Is it possible to write a formula that will - depending on the number in a cell - choose a particular IF formula
e.g.
if cell A5 = 6
Then in another cell - say F26 use this formula (below) which relates to another value in another cell (F25)
in cell =IF(F25>4.4,"C+",IF(F25>3.5,"C6", IF(F25>2.5,"C5",IF(F25>1.5,"C4","C1-3"))))

But if cell A5 = 5
Then apply a different formula in cell F26
=IF(F25>4.4,"B+",IF(F25>3.5,"B6", IF(F25>2.5,"B5",IF(F25>1.5,"B4","B1-3"))))

Any help would be appreciated

Cheers

[Pete_UK]

You could put this in F26:

=IF($A$5=6,IF(F25>4.4,"C+",IF(F25>3.5,"C6", IF(F25>2.5,"C5",IF(F25>1.5,"C4","C1-3")))),IF($A$5=5,IF(F25>4.4,"B+",IF(F25>3.5,"B6", IF(F25>2.5,"B5",IF(F25>1.5,"B4","B1-3")))),"n/a"))

Not sure why you have quotes around the cell references - I've left them in.

Hope this helps.

Pete

[FDibbins]

Hi, welcome to the forum

Perhaps this...
=IF(A5=6,IF(F25>4.4,"C+",IF(F25>3.5,"C6", IF(F25>2.5,"C5",IF(F25>1.5,"C4","C1-3")))),IF(F25>4.4,"B+",IF(F25>3.5,"B6", IF(F25>2.5,"B5",IF(F25>1.5,"B4","B1-3")))))

However, you can simplify this with a small table and a vlookup()...

	E	F	G
1		5	6
2	0	B1-3	C1-3
3	1.5	B4	C4
4	2.5	B5	C5
5	3.5	B6	C6
6	4.4	B+	C+

=VLOOKUP(F25,$E$2:$G$6,MATCH($A$5,$E$1:$G$1,0),1)

[corduroy82]

Pete

That works!

Cheers

[FDibbins]

Here is a shortened version of that same IF statement...
=IF(A5=6,"C","B")&IF(F25>4.4,"+",IF(F25>3.5,"6", IF(F25>2.5,"5",IF(F25>1.5,"4","1-3"))))