additional criteria in vlookup/if formula. formula error

This is the formula I'm using now and it works fine with no errors.....
=IF(D12=704,VLOOKUP(B12,Table1[#All],7),VLOOKUP(D12,'Pivot by Account'!$A$4:$D$10,4))



But I need to add an additional criteria.... if cell D12 is 704 and B12 on the original Table1 lookup is blank, I need look up a value in cell A12 and the output needs to be from a column in the table

=IF(D12=704,VLOOKUP(B12,Table1[#All],7),if(B12"",vlookup(a12,Table1[#All],7)),VLOOKUP(D12,'Pivot by Account'!$A$4:$D$10,4))

I am getting an error on this part ...B5""
forgive me if I didn't post my question correctly, this is my first post.

I can't visualise this without a sheet in front of me (can't work with jpgs...); but try (untested)

=IF(AND(D12=704, B12=""),VLOOKUP(B12,Table1[#All],7),VLOOKUP(D12,'Pivot by Account'!$A$4:$D$10,4))

OK. Try this:

=IF(AND(D2=704, B2=""),VLOOKUP(A2,Table1[#All],7),VLOOKUP(D2,'Pivot by Account'!$A$4:$D$10,4))

in G2, copied down.

You're welcome... and thanks!

=IF(AND(D2=704, B2=""),VLOOKUP(A2,Table1[#All],7,0),VLOOKUP(D2,'Pivot by Account'!$A$4:$D$10,4,0))
little modification to glen formula

0 means you want to find an "exact" match of the lookup value. You can also use FALSE as the argument:

VLOOKUP(A2,Table1[#All],7,0)
VLOOKUP(A2,Table1[#All],7,FALSE)

Both do the same thing but I prefer using 0 as it's less typing!

Using 1 or TRUE or omitting the argument means you want an approximate match of the lookup value:

VLOOKUP(A2,Table1[#All],7,1)
VLOOKUP(A2,Table1[#All],7,TRUE)
VLOOKUP(A2,Table1[#All],7)

This syntax is usually for looking up number values that fall within a range where there might not be an exact match. A good example of this is converting number grades to letter grades. For example:

Data Range

	A	B
1	Number Grade	Letter Grade
2	0	F
3	75	D
4	85	C
5	95	B
6	100	A

If we want to find the corresponding letter grade for the number 87 we would use:

=VLOOKUP(87,A2:B6,2)

Result = C

There is no exact match of the lookup value so the function uses the closest (approximate) match that is less than the lookup value.

Note: in order to work properly this syntax requires the lookup table be sorted in ascending order on the leftmost column.