Lookup - multiple criteria

Could you explain more what you are trying to do, instead of just saying "here's my file, you figure it out"

E2=IFERROR(LOOKUP(2,1/((Jan!$A$2:$A$7=$A2)*(Jan!$B$2:$B$7=$B2)*(Jan!$C$2:$C$7=$C2)*(Jan!$D$2:$D$7=$D2)),Jan!$E$2:$E$7),"")

Please Login or Register  to view this content.

F2=IFERROR(LOOKUP(2,1/((Feb!$A$2:$A$7=$A2)*(Feb!$B$2:$B$7=$B2)*(Feb!$C$2:$C$7=$C2)*(Feb!$D$2:$D$7=$D2)),Feb!$E$2:$E$7),"")

Please Login or Register  to view this content.

Try this and copy towards down

For January

in E2 and copy down

=SUMPRODUCT((Jan!A$2:A$7=A2)*(Jan!B$2:B$7=B2)*(Jan!C$2:C$7=C2)*(Jan!D$2:D$7=D2)*(Jan!E$2:E$7))

For February

in F2 and copy down

=SUMPRODUCT((Feb!A$2:A$7=A2)*(Feb!B$2:B$7=B2)*(Feb!C$2:C$7=C2)*(Feb!D$2:D$7=D2)*(Feb!E$2:E$7))

Originally Posted by AlKey

For January

in E2 and copy down

=SUMPRODUCT((Jan!A$2:A$7=A2)*(Jan!B$2:B$7=B2)*(Jan!C$2:C$7=C2)*(Jan!D$2:D$7=D2)*(Jan!E$2:E$7))

For February

in F2 and copy down

=SUMPRODUCT((Feb!A$2:A$7=A2)*(Feb!B$2:B$7=B2)*(Feb!C$2:C$7=C2)*(Feb!D$2:D$7=D2)*(Feb!E$2:E$7))

Looks like good candidates for SUMIFS.

With SUMIFS

=SUMIFS(Jan!E:E,Jan!A:A,A2,Jan!B:B,B2,Jan!C:C,C2,Jan!D:D,D2)

and

=SUMIFS(Feb!E:E,Feb!A:A,A2,Feb!B:B,B2,Feb!C:C,C2,Feb!D:D,D2)

Also if you change the headers for month in E1 and F1 to Jan and Feb you can use just one formula

enter formula in E2, pull it to the right and then down

=SUMIFS(INDIRECT("'"&E$1&"'!E:E"),INDIRECT("'"&E$1&"'!A:A"),$A2,INDIRECT("'"&E$1&"'!B:B"),$B2,INDIRECT("'"&E$1&"'!C:C"),$C2,INDIRECT("'"&E$1&"'!D:D"),$D2)