Compare a unique row of records against another

[nironto]

Hi All,
I am trying to compare one row of records (blue) against green as the reference base, where e.g. A3 to G3 are considered as 1 unique row.
Basically, I am trying to find out for the PN if any values has changed. Do not know what's wrong and still cannot get it correct.
Any help would be appreciated!


Regards,
Nironto

[Mazzaropi]

nironto, Good evening.

Using Excel allways you have a lot of different ways to do something.

My suggestion:

Q3 -->
=IF(CONCATENATE(A3,B3,C3,D3,E3,F3,G3)=CONCATENATE(I3,J3,K3,L3,M3,N3,O3),"MATCH","MISMATCH")

02-10-2015_Book1-OK.xlsx

Is that what you're looking for?
I hope it helps.

[nironto]

Thanks Marcílio Lobão!
It's getting close. But I need to compare against the whole reference list from row 3 to 43 if the record exists.
I tried below, but does not work.

=IF(CONCATENATE(A3,B3,C3,D3,E3,F3,G3)=CONCATENATE(I3,J3,K3,L3,M3,N3,O3: I43,J43,K43,L43,M43,N43,O43),"MATCH","MISMATCH")

Best Regards!

[FlameRetired]

If you array-enter this formula does it do what you want?

=IFERROR(IF(MATCH(A3&B3&C3&D3&E3&F3&G3,$I$3:$I$43&$J$3:$J$43&$K$3:$K$43&$L$3:$L$43&$M$3:$M$43&$N$3:$N$43&$O$3:$O$43,0),"Match"),"Mismatch")

If you aren’t familiar with array-entered formulas array enter means the formula must be committed from edit mode by simultaneously pressing and holding down Ctrl and Shift while hitting Enter.

[FlameRetired]

Or try this non-array formula.

=IF(A3="","",IF(COUNTIFS($I$3:$I$43,A3,$J$3:$J$43,B3,$K$3:$K$43,C3,$L$3:$L$43,D3,$M$3:$M$43,E3,$N$3:$N$43,F3,$O$3:$O$43,G3),"Match","Mismatch"))

[nironto]

Thanks FlameRetired Dave!
It works Wonders! I'll marked the thread as closed.

Regards,
Nironto

[FlameRetired]

@nironto

You are welcome. Thanks for the feedback and rep.