Assistance with Filtering out -m- tags from a Index

Assistance with Filtering out -m- tags from a Index when searching through a column of computers.

Here is my current code:
=IFERROR(INDEX(DataDump!A:A,SMALL(IF((DataDump!$K$2:$K$2001<>"6")*(DataDump!$B$2:$B$2001="Managed"),ROW(DataDump!$K$2:$K$2001),""),ROWS(L$2:L2))),"")

Breakdown
DataDump!A:A - is the list of computers to look through
DataDump!$K$2:$K$2001 - is the list of version numbers to look through and to show any version that is NOT 6.
DataDump!$B$2:$B$2001 - A list that will say either managed or unmanaged

This code above is currently working,
It looks through the list of computers, to find anything that is NOT a version 6, then looks for "Managed" in Column B, and then posts the resulting computer (That is managed and NOT version 6)

How can add to this formula to "ONLY review computers in DataDumpA:A that DO NOT CONTAIN -m-

I tried:
=IFERROR(INDEX(DataDump!A:A,SMALL(IF((DataDump!$A$2:$A$2001<>"*-M-*")*(DataDump!$K$2:$K$2001<>"6")*(DataDump!$B$2:$B$2001="Managed"),ROW(DataDump!$K$2:$K$2001),""),ROWS(L$2:L2))),"")

but it didn't work
My end game is for this not to count Macs

yes of course

Was testing:
=IFERROR(INDEX(DataDump!A:A,SMALL(IF((DataDump!$A$2:$A$2001<>"*-M-*")*(DataDump!$K$2:$K$2001<>"6")*(DataDump!$B$2:$B$2001="Managed"),ROW(DataDump!$K$2:$K$2001),""),ROWS(L$2:L2))),"")

I dropped the 2nd and 3rd query so now its:
=IFERROR(INDEX(DataDump!A:A,SMALL(IF((DataDump!$A$2:$A$2001<>"*-M-*"),ROW(DataDump!$K$2:$K$2001),""),ROWS(L$2:L2))),"")

It still doesn't work. It returns a computer but it shows the computers with -M- in them still. I got a feeling this is something really easy and right under my nose.

This didn't work either:
=IFERROR(INDEX(DataDump!A:A,SMALL(IF((DataDump!$K$2:$K$2001<>"6")*(DataDump!$B$2:$B$2001="Managed"),IF(DataDump!$A$2:$A$2001<>"*-M-*",ROW(DataDump!$K$2:$K$2001),""),""),ROWS(L$2:L2))),"")

ok so further into the research it would appear it doesn't want to take the Wild Card. Now I just gotta find a way around this...

Ok, so here is where the issue is"

Original code: (Works)
=IFERROR(INDEX(DataDump!A:A,SMALL(IF((DataDump!$K$2:$K$2001<>$A$10)*(DataDump!$B$2:$B$2001="Managed")*(DataDump!$Q$2:$Q$2001<>"Mac OS X"),ROW(DataDump!$K$2:$K$2001),""),ROWS(L$2:L2))),"")

When removing the asterisk it fails and displays all computers including the Mac's, it refuses to use a wild card.
=IFERROR(INDEX(DataDump!A:A,SMALL(IF((DataDump!$K$2:$K$2001<>$A$10)*(DataDump!$B$2:$B$2001="Managed")*(DataDump!$Q$2:$Q$2001<>"Mac*"),ROW(DataDump!$K$2:$K$2001),""),ROWS(L$2:L2))),"")

Try


=IFERROR(INDEX(DataDump!$A$1:$A$2001,SMALL(IF(NOT(ISNUMBER(SEARCH("*M*",DataDump!$Q$1:$Q$2001)))*(DataDump!$K$1:$K$2001<>"6")*(DataDump!$B$1:$B$2001="Managed"),ROW(DataDump!$K$1:$K$2001),""),ROWS(L$1:L1))),"")

@Tony, I'm certain you have told me this before .... but memory isn't what it was!!

This corrected it.
In the end, this is what I used:
=IFERROR(INDEX(DataDump!$A$1:$A$2001,SMALL(IF(ISERR(SEARCH("M",DataDump!$Q$1:$Q$2001))*(DataDump!$K$1:$K$2001<>$A$10)*(DataDump!$B$1:$B$2001="Managed"),ROW(DataDump!$K$1:$K$2001),""),ROWS(L$1:L1))),"")

Thank you
I will read up on using the ISERR and SEARCH functions for future reference.

Tony, out of curiosity.
We used IF(ISERR(SEARCH("M",DataDump!$Q$1:$Q$2001)) to remove any computers that have a -M- in them.

How would you do that in reverse?
Like only show computers that have the -M- but nothing else?

Cool, good to know. Thank you again Tony!