+ Reply to Thread
Results 1 to 42 of 42

SumProduct in closed workbook

  1. #1
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    SumProduct in closed workbook

    I am trying to count all instances of picking pm from closed workbook named "hit report", sheet "staff database" columns E and X, I have tried the below but it's not working

    =SUMPRODUCT(--('[Hit Report 27.xlsm]Staff Database'!$E$1:$E$2000="Picking"),--('[Hit Report 27.xlsm]Staff Database'!$X$1:$X$2000="PM"))

    Using sum product as countifs formula didn't work in closed workbook. Can anyone help?
    Last edited by Ity007; 05-17-2016 at 08:56 PM.

  2. #2
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    What does "it's not working" mean?

    Do you get an error? An unexpected result? Something else?
    Biff
    Microsoft MVP Excel
    Keep It Simple Stupid

    Let's Go Pens. We Want The Cup.

  3. #3
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    I get N/A in the cell

  4. #4
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    Are there any #N/A errors in either of the referenced ranges?

  5. #5
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    There are no n/a errors in the referenced cells, but the report is all formulated

  6. #6
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    I am unable to duplicate the #N/A result.

    I created the file Hit Report 27.xlsx and modified your formula with the new file extension and it gave the correct result both when the source file was open or closed:

    Open:

    =SUMPRODUCT(--('[Hit Report 27.xlsx]Staff Database'!$E$1:$E$2000="Picking"),--('[Hit Report 27.xlsx]Staff Database'!$X$1:$X$2000="PM"))


    Closed:

    =SUMPRODUCT(--('C:\TV\[Hit Report 27.xlsx]Staff Database'!$E$1:$E$2000="Picking"),--('C:\TV\[Hit Report 27.xlsx]Staff Database'!$X$1:$X$2000="PM"))

  7. #7
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    Hi Tony,

    I have tried the formula and you are correct when the range hits a #N/A, it doesn't total. how can I formulate the above so it ignores #N/A and still totals. thanks

  8. #8
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    Quote Originally Posted by Ity007 View Post
    I have tried the formula and you are correct when the range hits a #N/A, it doesn't total.
    Which range has the #N/A errors?

  9. #9
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    both ranges has multiple #n/a errors

  10. #10
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    OK, you'll have to use an array formula** in that case.

    =SUMPRODUCT(--(IFERROR('[Hit Report 27.xlsx]Staff Database'!$E$1:$E$2000,0)="Picking"),--(IFERROR('[Hit Report 27.xlsx]Staff Database'!$X$1:$X$2000,0)="PM"))

    ** array formulas need to be entered using the key
    combination of CTRL,SHIFT,ENTER (not just ENTER).
    Hold down both the CTRL key and the SHIFT key
    then hit ENTER.

  11. #11
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    The formula has worked it is ignoring all #n/a solved thanks. I am trying to sum product of column w of any entries of perm and perm flex. I have tried two formulas but both return 0.

    =SUMPRODUCT(--(IFERROR('[Hit Report 27.xlsx]Staff Database'!$E$1:$E$2000,0)="Picking"),--(IFERROR('[Hit Report 27.xlsx]Staff Database'!$X$1:$X$2000,0)="PM"),--(IFERROR('[Hit Report 27.xlsx]Staff Database'!$W$1:$W$2000,0)="*Perm*"),--(IFERROR('[Hit Report 27.xlsx]Staff Database'!$W$1:$W$2000,0)="Perm Flex")))

    the *perm* works in countifs but returning 0 in below case

    =SUMPRODUCT(--(IFERROR('[Hit Report 27.xlsx]Staff Database'!$E$1:$E$2000,0)="Picking"),--(IFERROR('[Hit Report 27.xlsx]Staff Database'!$X$1:$X$2000,0)="PM"),--(IFERROR('[Hit Report 27.xlsx]Staff Database'!$W$1:$W$2000,0)="*Perm*"))

  12. #12
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    *Perm*

    Are you using the * as a wildcard?

    If so, the SUMPRODUCT function doesn't work with wildcards.

    Try that expression like this:

    IFERROR(--ISNUMBER(SEARCH("Perm",'[Hit Report 27.xlsx]Staff Database'!$W$1:$W$2000)),0)

  13. #13
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    Thanks Tony works like a treat
    Last edited by Ity007; 05-19-2016 at 01:30 PM.

  14. #14
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    You're welcome. Thanks for the feedback!

  15. #15
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    Hi Tony, I just wanted to know is there a way of counting for two different variables together example "kw" and "Agency" from the same column.
    something along the lines of below, or is it not possible?

    =SUMPRODUCT(--IFERROR(--ISNUMBER(SEARCH("SUPER",'[KRONOS Staffing Database.xls]staff database'!$F$1:$F$3000)),0),--(IFERROR('[KRONOS Staffing Database.xls]staff database'!$X$1:$X$3000,0)="2-10pm"),--IFERROR(--ISNUMBER(SEARCH("KW",'[KRONOS Staffing Database.xls]staff database'!$W$1:$W$3000)),0),--IFERROR(--ISNUMBER(SEARCH("AGENCY",'[KRONOS Staffing Database.xls]staff database'!$W$1:$W$3000)),0) )

    Thanks

  16. #16
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    You want the condition to be if the range = "kw" or "Agency" ?

  17. #17
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    yes if the condition is "kw" or "agency" in the same column then count using the previous sum product formula

  18. #18
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    Maybe this...

    =SUMPRODUCT(--IFERROR(--ISNUMBER(SEARCH("SUPER",'[KRONOS Staffing Database.xls]staff database'!$F$1:$F$3000)),0),--(IFERROR('[KRONOS Staffing Database.xls]staff database'!$X$1:$X$3000,0)="2-10pm"),--ISNUMBER(MATCH('[KRONOS Staffing Database.xls]staff database'!$W$1:$W$3000,{"KW","Agency"},0)))

    You only need the IFERROR function on ranges that have error values in them.

  19. #19
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    Thanks Tony works correctly, one last thing i am trying to do is count column "A", where value is greather than for example 190000

    =SUMPRODUCT(--(IFERROR('[KRONOS Staffing Database.xls]staff database'!$A$1:$A$3000,0)=">190000"),--(IFERROR('[KRONOS Staffing Database.xls]staff database'!$X$1:$X$3000,0)="2-10pm"),--IFERROR(--ISNUMBER(SEARCH("agency",'[KRONOS Staffing Database.xls]staff database'!$W$1:$W$3000)),0) )

  20. #20
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    Like this...

    =SUMPRODUCT(--(IFERROR('[KRONOS Staffing Database.xls]staff database'!$A$1:$A$3000,0)>190000),--(IFERROR('[KRONOS Staffing Database.xls]staff database'!$X$1:$X$3000,0)="2-10pm"),--IFERROR(--ISNUMBER(SEARCH("agency",'[KRONOS Staffing Database.xls]staff database'!$W$1:$W$3000)),0))

  21. #21
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    Thanks Tony if i was use greater than date would it be used as below

    =SUMPRODUCT(--(IFERROR([Hit27.xlsx]Sheet1!$V$1:$V$41,0)>14/2/2016),--(IFERROR([Hit27.xlsx]Sheet1!$X$1:$X$41,0)="PM"),--IFERROR(--ISNUMBER(SEARCH("agency",[Hit27.xlsx]Sheet1!$W$1:$W$41)),0))

  22. #22
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    Why not put the date in a cell then refer to that cell:

    A1 = 14/2/2016

    =SUMPRODUCT(--(IFERROR([Hit27.xlsx]Sheet1!$V$1:$V$41,0)>A1)...

    Otherwise...

    =SUMPRODUCT(--(IFERROR([Hit27.xlsx]Sheet1!$V$1:$V$41,0)>DATE(2016,2,14))...

  23. #23
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    hi Tony

    I am trying to sumproduct if in column G two numbers exist, 4500 and 4456, however the below does not sum


    =SUMPRODUCT(--IFERROR(--ISNUMBER(MATCH('[KRONOS Staffing Database.xls]staff database'!$G$1:$G$3000, {"4500","4456"})),0),--(IFERROR('[KRONOS Staffing Database.xls]staff database'!$X$1:$X$3000,0)="2-10pm"),--ISNUMBER(MATCH('[KRONOS Staffing Database.xls]staff database'!$W$1:$W$3000, {"Agency","KW"},0)))

  24. #24
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    hi Tony

    I am trying to sumproduct if in column G two numbers exist, 4500 and 4456, however the below does not sum


    =SUMPRODUCT(--IFERROR(--ISNUMBER(MATCH('[KRONOS Staffing Database.xls]staff database'!$G$1:$G$3000, {"4500","4456"})),0),--(IFERROR('[KRONOS Staffing Database.xls]staff database'!$X$1:$X$3000,0)="2-10pm"),--ISNUMBER(MATCH('[KRONOS Staffing Database.xls]staff database'!$W$1:$W$3000, {"Agency","KW"},0)))

  25. #25
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    Quote Originally Posted by Ity007 View Post
    =SUMPRODUCT(--IFERROR(--ISNUMBER(MATCH('[KRONOS Staffing Database.xls]staff database'!$G$1:$G$3000, {"4500","4456"})),0),--(IFERROR('[KRONOS Staffing Database.xls]staff database'!$X$1:$X$3000,0)="2-10pm"),--ISNUMBER(MATCH('[KRONOS Staffing Database.xls]staff database'!$W$1:$W$3000, {"Agency","KW"},0)))
    Try removing the quotes from around {"4500","4456"}...

    {4500,4456}

  26. #26
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    I have removed the quaotes and it has given me a figure of 139 but the figure should be 1. what I am trying to achieve is if there is a instance of 4500 or 4456 who are agency or kw and on the 2-10pm shift then count only these rows

  27. #27
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    Maybe this...

    =SUMPRODUCT(--ISNUMBER(MATCH('[KRONOS Staffing Database.xls]staff database'!$G$1:$G$3000,{4500,4456},0)),--(IFERROR('[KRONOS Staffing Database.xls]staff database'!$X$1:$X$3000,0)="2-10pm"),--ISNUMBER(MATCH('[KRONOS Staffing Database.xls]staff database'!$W$1:$W$3000,{"Agency","KW"},0)))

  28. #28
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    Hi Tony

    I am trying to add up perms, kw along with agency members who have been here greater than 2016,2,4 in the packing hall on the pm shift the resulting query brings up 0, can you help. DATES is present in column V1:V41

    Please Login or Register  to view this content.
    Last edited by Ity007; 06-09-2016 at 12:35 PM.

  29. #29
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    Quote Originally Posted by Ity007 View Post
    =SUMPRODUCT(--ISNUMBER(MATCH([Hit27.xlsx]Sheet1!$W$1:$W$41, {"PERM","KW"},0)),--(IFERROR([Hit27.xlsx]Sheet1!$X$1:$X$41,0)="PM"),--(IFERROR([Hit27.xlsx]Sheet1!$D$1:$D$41,0)="Packing hall"),--IFERROR(--ISNUMBER(SEARCH([Hit27.xlsx]Sheet1!$W$1:$W$41, {"AGENCY"})>=DATE(2016,2,4)),0))
    This doesn't look right:

    --ISNUMBER(SEARCH([Hit27.xlsx]Sheet1!$W$1:$W$41, {"AGENCY"})>=DATE(2016,2,4))

    Explain what you want that expression to do.

  30. #30
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    i want this expression to search for agency staff in "W" column who have been here greater or equalto than "V" column which stores dates
    --ISNUMBER(SEARCH([Hit27.xlsx]Sheet1!$W$1:$W$41, {"AGENCY"}),([Hit27.xlsx]Sheet1!$V$1:$V$41)>=DATE(2016,2,4)))

  31. #31
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    Those are 2 separate tests.

    --ISNUMBER(SEARCH("Agency",[Hit27.xlsx]Sheet1!$W$1:$W$41))


    --([Hit27.xlsx]Sheet1!$V$1:$V$41>=DATE(2016,2,4))

  32. #32
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    yes i have tried the below which is giving me 3 but the number should be 13

    =SUMPRODUCT(--ISNUMBER(SEARCH("Agency",[Hit27.xlsx]Sheet1!$W$1:$W$41))--([Hit27.xlsx]Sheet1!$V$1:$V$41>=DATE(2016,2,4)),--(IFERROR([Hit27.xlsx]Sheet1!$X$1:$X$41,0)="PM"),--(IFERROR([Hit27.xlsx]Sheet1!$D$1:$D$41,0)="Packing hall"),--ISNUMBER(MATCH([Hit27.xlsx]Sheet1!$W$1:$W$41, {"perm","keyworker"},0)))

  33. #33
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    I would need to see the file to figure out what you're trying to do.

    However, I won't download files >20kb.

    If the file is bigger than 20kb and you're able to post it I would recommend you start a new thread which will give you a better chance of attracting more users who would be willing to download your file. People are less likely to read a thread with very many posts like this one.

  34. #34
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    I have attached the file, if you have any questions let me know
    Attached Files Attached Files

  35. #35
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    Ok, I found some conflicting tests...

    Here's the formula in I2:

    =SUMPRODUCT(--ISNUMBER(SEARCH("Agency",Sheet1!$C$1:$C$41))--(Sheet1!$B$1:$B$41>=DATE(2016,2,4)),--(IFERROR(Sheet1!$D$1:$D$41,0)="PM"),--(IFERROR(Sheet1!$A$1:$A$41,0)="Packing hall"),--ISNUMBER(MATCH(Sheet1!$C$1:$C$41, {"perm","keyworker"},0)))

    The 2 highlighted tests conflict with each other.

    Essentially, what it's saying is:

    Count cells that contain BOTH Agency AND perm or keyworker

    Both conditions will NEVER be true at the same time so the formula will always return 0.

  36. #36
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    So is it possible to count Agency with hire date and Perm or keyworker regardless of the hire date column together

  37. #37
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    I want to combine the below formulas into 1

    =SUMPRODUCT(--(IFERROR(Sheet1!$D$1:$D$41,0)="PM"),--(IFERROR(Sheet1!$A$1:$A$41,0)="Packing hall"),--ISNUMBER(MATCH(Sheet1!$C$1:$C$41, {"perm","keyworker"},0)))

    =SUMPRODUCT(--(IFERROR(Sheet1!$B$1:$B$41,0)>=DATE(2016,2,4)),--(IFERROR(Sheet1!$D$1:$D$41,0)="PM"),--ISNUMBER(MATCH(Sheet1!$A$1:$A$41, {"Packing Hall"},0)),--IFERROR(--ISNUMBER(SEARCH("Agency",Sheet1!$C$1:$C$41)),0))

    enter in h3 and i3
    Last edited by Ity007; 06-09-2016 at 03:02 PM.

  38. #38
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    Maybe this is what you mean:

    Sheet1!$C$1:$C$41 = perm OR keyworker OR Agency

  39. #39
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    Sorry no, this is combining perm or keyworker or agency but it needs to combine perm or keyworker along with agency dependant on date in column B for greater than 02/04/2016

  40. #40
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    Here's some of the data in column C...

    Data Range
    C
    2
    perm
    3
    KeyWorker
    4
    KeyWorker
    5
    Agency
    6
    KeyWorker
    7
    KeyWorker
    8
    Agency
    9
    perm
    10
    KeyWorker
    11
    Agency
    12
    perm
    13
    perm
    14
    Agency
    15
    Agency


    Each cell has a single entry.

    You want to test that the cell contains Agency and then later in the formula you want to test if the same cells contain either perm or keyworker. Both of these conditions have to be true in order to be counted.

    However, this will NEVER be true so the formula will always return 0.

    This is what's it's trying to do:

    =AND(C2="Agency",OR(C2={"Perm","KeyWorker"}))

    In simple terms, C2 can not contain both Agency or Perm or KeyWorker at the same time.

  41. #41
    Registered User
    Join Date
    04-27-2016
    Location
    England
    MS-Off Ver
    2010
    Posts
    36

    Re: SumProduct in closed workbook

    so Tony is the best solution to keep both formulas seperate one to =SUMPRODUCT(--(IFERROR(Sheet1!$D$1:$D$41,0)="PM"),--(IFERROR(Sheet1!$A$1:$A$41,0)="Packing hall"),--ISNUMBER(MATCH(Sheet1!$C$1:$C$41, {"perm","keyworker"},0)))

    and other to
    =SUMPRODUCT(--(IFERROR(Sheet1!$B$1:$B$41,0)>=DATE(2016,2,4)),--(IFERROR(Sheet1!$D$1:$D$41,0)="PM"),--ISNUMBER(MATCH(Sheet1!$A$1:$A$41, {"Packing Hall"},0)),--IFERROR(--ISNUMBER(SEARCH("Agency",Sheet1!$C$1:$C$41)),0))

  42. #42
    Forum Expert Tony Valko's Avatar
    Join Date
    12-31-2011
    Location
    Pittsburgh
    MS-Off Ver
    2002, 2007:2013
    Posts
    18,890

    Re: SumProduct in closed workbook

    As long as you get the correct results.

    Based on the data in your file you don't need those IFERROR functions.

    =SUMPRODUCT(--(Sheet1!$D$1:$D$41="PM"),--(Sheet1!$A$1:$A$41="Packing hall"),--ISNUMBER(MATCH(Sheet1!$C$1:$C$41,{"perm","keyworker"},0)))

    =SUMPRODUCT(--(Sheet1!$B$1:$B$41>=DATE(2016,2,4)),--(Sheet1!$D$1:$D$41="PM"),--(Sheet1!$A$1:$A$41="Packing Hall"),--(Sheet1!$C$1:$C$41="Agency"))

+ Reply to Thread

Thread Information

Users Browsing this Thread

There are currently 1 users browsing this thread. (0 members and 1 guests)

Similar Threads

  1. Alternatives to Sumproduct(Sumif( for use with closed workbook
    By soberguy in forum Excel Formulas & Functions
    Replies: 1
    Last Post: 05-30-2014, 11:14 AM
  2. Replies: 0
    Last Post: 03-27-2014, 12:38 PM
  3. Using SUMPRODUCT to count values in closed workbook
    By Lifeseeker in forum Excel Programming / VBA / Macros
    Replies: 2
    Last Post: 01-04-2012, 02:34 PM
  4. Sumproduct refers to named ranges in closed workbook
    By Bob@Sun in forum Excel Formulas & Functions
    Replies: 8
    Last Post: 08-25-2010, 11:35 AM
  5. SUMPRODUCT to SUM variable range in closed workbook
    By opopanax666 in forum Excel General
    Replies: 2
    Last Post: 02-12-2010, 06:42 AM
  6. Sumproduct Not Working In Closed Workbook & shows #N/A
    By jasgat in forum Excel Formulas & Functions
    Replies: 14
    Last Post: 07-15-2008, 10:17 PM
  7. Sumproduct Does Not Work In Closed Workbook
    By Kumara_faith in forum Excel Formulas & Functions
    Replies: 2
    Last Post: 05-13-2008, 03:36 PM

Bookmarks

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts

Search Engine Friendly URLs by vBSEO 3.6.0 RC 1