Need Count If Unique help

[NS4Excel]

I have a file that I attempted to attach here but the attach file feature is not working for me at the moment.

My file has 2 worksheets: List and Count.

Worksheet List has 6 columns (A-F).

Worksheet Count:
Col A has unique items in it.
Cell D3: I need a formula that will count the unique items in List Col B if List Col A is equal to Count A3.
Cell E3: I need a formula that will count the unique items in List Col B and List Col C if List Col A is equal to Count A3.
Cell F3: I need a formula that will count the unique items in List Col B if List Col F<>0 and if List Col A is equal to Count A3.
Cell G3: I need a formula that will count the unique items in List Col B and List Col C if List Col F<>0 and if List Col A is equal to Count A3.


Any help is appreciated.

[JBeaucaire]

Click on GO ADVANCED and then scroll down to Manage Attachments to open the upload window.

File should be small, do not unnecessarily upload data-laden workbooks. ZIP them if needed.

[NS4Excel]

I uploaded it but I cannot attach it. The Attach feature in each post is not working for me.

[NS4Excel]

Apparently I didn't need to do an extra attach step. Thanks.

[JBeaucaire]

D3:
=SUM(INDEX((List!$A$1:$A$322=$A3)*(MATCH(List!$B$1:$B$322,List!$B$1:$B$322,0)=ROW(List!$A$1:$A$322)),0))

E3:
=SUM(INDEX((List!$A$1:$A$322=$A3)*(MATCH(INDEX(List!$B$1:$B$322&"|"&List!$C$1:$C$322,0),INDEX(List!$B$1:$B$322&"|"&List!$C$1:$C$322,0),0)=ROW(List!$A$1:$A$322)),0))

F3:
=SUM(INDEX((List!$A$1:$A$322=$A3)*(List!$F$1:$F$322<>0)*(MATCH(INDEX(List!$B$1:$B$322&"|"&List!$C$1:$C$322,0),INDEX(List!$B$1:$B$322&"|"&List!$C$1:$C$322,0),0)=ROW(List!$A$1:$A$322)),0))

G3:

=SUM(INDEX((List!$A$1:$A$322=$A3)*(List!$F$1:$F$322<>0)*(MATCH(List!$B$1:$B$322,List!$B$1:$B$322,0)=ROW(List!$A$1:$A$322)),0))

H3:
=SUM(INDEX((List!$A$1:$A$322=$A3)*(List!$F$1:$F$322<>0)*(MATCH(INDEX(List!$D$1:$D$322&"|"&List!$E$1:$E$322,0),INDEX(List!$D$1:$D$322&"|"&List!$E$1:$E$322,0),0)=ROW(List!$A$1:$A$322)),0))

...copied down.