Transpose Formula

[pahickham]

Hey All,

I'm looking for a formula that can both transpose and filter, so there's no repeats, one column of data (B4:B38) to the row (B74:Z74). Also I'm in need of another formula that can transfer the data from column (C4:C38) to column (B75:B81) if the data applies, if no then I'd like for it to display a 0. I tried using the transpose command but I cant get it to work. Any help would be much appreciated. Attached is an example of what I'm looking for.

[Glenn Kennedy]

A68 should read jason.


1. An array formula in B74:
=IFERROR(INDEX($B$4:$B$38,MATCH(0,IF($B$4:$B$38<>"",COUNTIF($A$74:A74,$B$4:$B$38)),0)),"")



2. Kill the merged cells, and it's easy: in B75, copied across and down:

=SUMIFS($C$4:$C$38,$A$4:$A$38,$A75,$B$4:$B$38,B$74)

Array Formulae are a little different from ordinary formulae in that they MUST be confirmed in the FIRST CELL ONLY by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. After that, the array can be dragged down as normal, to cover the desired range.

You will know the array is active when you see curly brackets { } - or "curly braces" for those of you in the USA, or "flower brackets" for those of you in India - appear around the outside of your formula. If you do not use CTRL+SHIFT+ENTER you will (almost always) get an error message or an incorrect answer. Press F2 on that cell and try again.

Don't type the curly brackets yourself - it won't work...

[pahickham]

Thank you! This worked perfectly!

[Glenn Kennedy]

You're welcome!!

[pahickham]

Hey I've got one more question. If I were to move that bottom section that you typed the code for to another sheet (meaning I would know have a sheet1 and sheet2) would changing the formula be as simple as typing Sheet1 in front?
ex:
=SHEET1(IFERROR(INDEX($B$4:$B$38,MATCH(0,IF($B$4:$B$38<>"",COUNTIF($A$74:A74,$B$4:$B$38)),0)),""))
or how would I type it for that formula and the other?

[Glenn Kennedy]

No...

=IFERROR(INDEX('Sheet1'!$B$4:$B$38,MATCH(0,IF('Sheet1'!$B$4:$B$38<>"",COUNTIF($A$74:A74,'Sheet1'!$B$4:$B$38)),0)),"")

should do it...

[pahickham]

You sir are a lifesaver! Thank you again and have an amazing day!

[Glenn Kennedy]

=IFERROR(INDEX('Sheet1'!$B$4:$B$38,MATCH(0,IF('Sheet1'!$B$4:$B$38<>"",COUNTIF($A$74:A74,'Sheet1'!$B$4:$B$38)),0)),"")

I forgot to add that the bit in red should refer to the cell IMMEDIATELY TO THE LEFT of the first cell that you want to get the results in... Make sure that you get the $ signs right!!