How can I filter a column with more than 2 words present

[faizzsheikh]

Hello Friends!

Hope you can help me with this

Eg. In Column a I have product descriptions

Column A

1 - SMZ610 Super Bass Stereo In - ear Earphone with 3.5mm Plug
2 - buy leather iphone case for cheap
3 - PortableDB In - ear Stereo Ear Hook Earphone Sports Headset 3.5mm Plug with Carrying Bag
4 - High Fidelity Effect Noodle Cable In - ear Earphone for Various Phones
5 - iphone case made with genuine leather - exclusive gift for your loved ones
6 - Portable Mini LCD Screen 8GB USB MP3 Player with FM Radio / REC / MIC
7 - Portable 4.3 inch TFT 4GB MP5 Player Game Console FM Radio with TV - OUT and 3.0MP Camera


From the above column I want cells which include all 3 words iphone, leather and case

Thanks for your support!

[Aardigspook]

If your data starts in A1, put this in B1 and drag down. It will give you what's in column A if that contains all three of your search terms, or return 'n/a' if not.

Please Login or Register  to view this content.

Edit: sorry, somehow or other I missed the essential AND:
=IF(AND(NOT(ISERROR(SEARCH({"iphone","leather","case"},A1)))),A1,"n/a")
But you got a better solution from Glenn anyway.

[faizzsheikh]

Thanks for your response.

Not worked, I tried your formula but its returning cells that have only iphone mentioned in it. I want to get cells that has all 3 words present in it.

For instant I want "Order case built with leather for your iphone"
I dont want "buy case cover for iphone as a gift for your loved ones"

[Glenn Kennedy]

Assuming data in A2:

=IFERROR(INDEX(A:A,AGGREGATE(15,6,ROW($A$2:$A$8)/(ISNUMBER(SEARCH("leather",$A$2:$A$8))*ISNUMBER(SEARCH("iphone",$A$2:$A$8))*ISNUMBER(SEARCH("case",$A$2:$A$8))),ROWS($1:1))),"")

[Glenn Kennedy]

Apologies. I mis-read your profile. You don't have Excel 2010+, so don't have aggregate. Use this array formula:

=IFERROR(INDEX(A:A,SMALL(IF(ISNUMBER(SEARCH("leather",$A$2:$A$8)),IF(ISNUMBER(SEARCH("iphone",$A$2:$A$8)),IF(ISNUMBER(SEARCH("case",$A$2:$A$8)),ROW($A$2:$A$8)))),ROWS($1:1))),"")

Array Formulae are a little different from ordinary formulae in that they MUST be confirmed in the FIRST CELL ONLY by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. After that, the array can be dragged down as normal, to cover the desired range.

You will know the array is active when you see curly brackets { } - or "curly braces" for those of you in the USA, or "flower brackets" for those of you in India - appear around the outside of your formula. If you do not use CTRL+SHIFT+ENTER you will (almost always) get an error message or an incorrect answer. Press F2 on that cell and try again.

Don't type the curly brackets yourself - it won't work...

[faizzsheikh]

Apologies. I mis-read your profile. You don't have Excel 2010+, so don't have aggregate. Use this array formula:

=IFERROR(INDEX(A:A,SMALL(IF(ISNUMBER(SEARCH("leather",$A$2:$A$8)),IF(ISNUMBER(SEARCH("iphone",$A$2:$A$8)),IF(ISNUMBER(SEARCH("case",$A$2:$A$8)),ROW($A$2:$A$8)))),ROWS($1:1))),"")

Array Formulae are a little different from ordinary formulae in that they MUST be confirmed in the FIRST CELL ONLY by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. After that, the array can be dragged down as normal, to cover the desired range.

You will know the array is active when you see curly brackets { } - or "curly braces" for those of you in the USA, or "flower brackets" for those of you in India - appear around the outside of your formula. If you do not use CTRL+SHIFT+ENTER you will (almost always) get an error message or an incorrect answer. Press F2 on that cell and try again.

Don't type the curly brackets yourself - it won't work...

Hello Glenn,

Thanks a lot for your support, your formula worked perfectly!

I was assuming it could get solved by an 'advanced filter' or something, but it is way difficult. Thanks again, you are a savior!

[Glenn Kennedy]

You're welcome.

---

If that takes care of your original question, please select "Thread Tools" from the menu link above and mark this thread as SOLVED.

It'd also be appreciated if you were to click the Add Reputation button at the foot of any of the posts of all members who helped you reach a solution.

[samba_ravi]

If you want to go with advance filters
In the attached file do the following
Data > Advanced (Filter)
select A10:A17 under listrange
select A1:A7 under Criteria Range
Click OK