To pick next PIC once the first PIC hits quota

Individual assigned case based on country and daily target.
Once individual A hits the quota, next person shall pick up the task.

Issue 1:
Example:
Daily Target for Thailand is 10 cases.
Thailand case handled by Ali & Barbara. Thailand case will be assigned to Ali up to 5 case. 6th - 10th case will be assigned to Barbara. The balance of case will be do tomorrow so, the PIC is TOMORROW.

I manage to found the formula to assign 1st case to 5th case to Ali. Stuck at 6th - 10th & continue case PIC assignment.

Issue 2:
Example:
Daily Target for Malaysia is 8 cases and handled by Cendect only. If Malaysia has less than 8 case, Cendect is required to do Thailand case to hit his quota which 8 case.

Formula to assign Malaysia case no issue. Problem is how to assign Thailand case to Cendect ?

Your current setup for Cendect and Gren's optional countries makes a formula difficult, so I would advise a new approach. I built a separate table in A29:D39 on your "Guide" sheet. This new table pulls numbers from your existing data but ranks the PIC's for each country in the order that they should be assigned cases and lists the number of cases each one can handle per country. With this table in place, you can use the following formula in C2 on "Case". It must be array-entered (confirmed with Ctrl + Shift + Enter instead of Enter):

=IFERROR(INDEX(Guide!$B$30:$B$39,SMALL(IF((COUNTIFS($C$1:$C1,Guide!$B$30:$B$39,$B$1:$B1,Guide!$A$30:$A$39) < Guide!$D$30:$D$39)*([@Country]=Guide!$A$30:$A$39),ROW(Guide!$D$30:$D$39)-ROW(Guide!$D$30)+1),1)),"Tomorrow")

Fill it down through the table on "Case" and it should match what you're looking for without relying on any of the info in F:K of "Case". The only exception is Henry's Japan assignments. Leaving both Japan and Henry's totals blank on the "Guide" sheet fails to indicate whether you intend Henry to handle all Japan cases or no Japan cases. The formula treats a blank as zero, so he has not been assigned cases. If you want him to have cases, enter a target for Japan in B7 or for Henry in B17 and the formula will give him cases. If you want to assign him all of the Japan cases, use the following in B7:

=COUNTIF(Table1[Country],A7)

Take a look at the attachment to see if the new approach is helpful:

You describe two separate effects:

Random: Barbara, Cendect, Ali, Cendect, Barbara, Barbara, Ali, Barbara, etc., randomly picking from the options until targets are reached.

or

Rotational: Ali, Barbara, Cendect, Ali, Barbara, Cendect, Ali, Barbara, etc., keeping the same order until targets are reached.

Either choice is possible. Whichever formula you prefer should go in C2 and needs to be array-entered, then filled down (if the table doesn't fill it down automatically):

Random (hit F9 to re-shuffle)
=IFERROR(INDEX(Guide!$B$30:$B$39,SMALL(IF((COUNTIFS($C$1:$C1,Guide!$B$30:$B$39,$B$1:$B1,Guide!$A$30:$A$39) < Guide!$D$30:$D$39)*([@Country]=Guide!$A$30:$A$39),ROW(Guide!$D$30:$D$39)-ROW(Guide!$D$30)+1),RANDBETWEEN(1,SUMPRODUCT(--(((COUNTIFS($C$1:$C1,Guide!$B$30:$B$39,$B$1:$B1,Guide!$A$30:$A$39) < Guide!$D$30:$D$39)*([@Country]=Guide!$A$30:$A$39))=1))))),"Tomorrow")

Rotational:
=IFERROR(INDEX(Guide!$B$30:$B$39,SMALL(IF(IF((COUNTIFS($C$1:$C1,Guide!$B$30:$B$39,$B$1:$B1,Guide!$A$30:$A$39) < Guide!$D$30:$D$39)*([@Country]=Guide!$A$30:$A$39),COUNTIFS($C$1:$C1,Guide!$B$30:$B$39,$B$1:$B1,Guide!$A$30:$A$39))=MIN(IF((COUNTIFS($C$1:$C1,Guide!$B$30:$B$39,$B$1:$B1,Guide!$A$30:$A$39) < Guide!$D$30:$D$39)*([@Country]=Guide!$A$30:$A$39),COUNTIFS($C$1:$C1,Guide!$B$30:$B$39,$B$1:$B1,Guide!$A$30:$A$39))),ROW(Guide!$D$30:$D$39)-ROW(Guide!$D$30)+1),1)),"Tomorrow")