List out historical data with INDEX x MATCH x ?

[pcgk33]

Hi guys, i'm working on a search function on my worksheet. so basically, i have a database and on the main page, i would like to type in a name and a style then have excel to find the most recent 10 entries within my database by providing me "item name, style, date, counts". Can anyone show me how? thanks in advance!

my current method is: enter name and style then {index(time/date/counts, match(name,name*style,style)}, but i can only get 1 line out and couldn't get the rest (ideally, 10 lines)

[AliGW]

Welcome to the forum!

Will you please attach a sample Excel workbook? We are not able to work with or manipulate a picture of one and nobody wants to have to recreate your data from scratch.

1. Make sure that your sample data are REPRESENTATIVE of your real data. The use of unrepresentative data is very frustrating and can lead to long delays in reaching a solution.

2. Make sure that your desired results are also shown (mock up the results manually).

3. Make sure that all confidential data is removed or replaced with dummy data first (e.g. names, addresses, E-mails, etc.).

4. Try to avoid using merged cells as they cause lots of problems.

Unfortunately the attachment icon doesn't work at the moment, so to attach an Excel file you have to do the following: just before posting, scroll down to Go Advanced and then scroll down to Manage Attachments. Now follow the instructions at the top of that screen.

Please pay particular attention to point 2 (above): without an idea of your intended outcomes, it is often very difficult to offer appropriate advice.

[FDibbins]

Agree that a sample WB is needed here, also showing expected outcome.

You will probably need the INDEX/IF/SMALL() ARRAY function for this

[pcgk33]

Thank you!! Ali & Ford!

[FDibbins]

I changed my approach after I saw your data. If you would be OK with using a helper column (which you can hide if needed), you can simplify this greatly

DB G4=IF(AND(B4=FP!$C$5,DB!C4=FP!$D$5),G3+1,G3)
copied down as needed
This is the helper that creates a unique ID for all entries matching your criteria

To extract the data (H8 is wrong btw)...

	B	C	D	E
7		Purchase Date	Purchase Price	Invoice Number
8	1	11/7/2018	28000	181101-DC041
9	2	11/4/2018	14000	181101-DC035
10	3	11/3/2018	17500	181101-DC034
11	4
12	5
13	6
14	7
15	8
16	9
17	10

C8=IFERROR(INDEX(DB!$B$4:$F$23,MATCH(MAX(DB!$G:$G)-10+(11-$B8),DB!$G$4:$G$23,0),MATCH(C$7,DB!$B$3:$F$3,0)),"")
copied down and across as needed

[AliGW]

Here's a different approach that uses no helper columns:

Excel 2016 (Windows) 32 bit

	H	I	J
7	Purchase Date	Purchase Price	Invoice Number
8	03/11/2018	17500	181101-DC034
9	04/11/2018	14000	181101-DC035
10	07/11/2018	28000	181101-DC041

Sheet: FP

Excel 2016 (Windows) 32 bit

	H
8	=IFERROR(INDEX(DB!$D$1:$D$1000,AGGREGATE(15,6,ROW($4:$1000)/((DB!$B$4:$B$1000=H$5)*(DB!$C$4:$C$1000=I$5)),ROW(1:1))),"")

Sheet: FP

Excel 2016 (Windows) 32 bit

	I
8	=IFNA(LOOKUP(2,1/((DB!$B$4:$B$1000=H$5)*(DB!$C$4:$C$1000=I$5)*(DB!$D$4:$D$1000=$H8)),DB!$E$4:$E$1000),"")

Sheet: FP

Excel 2016 (Windows) 32 bit

	J
8	=IFNA(LOOKUP(2,1/((DB!$B$4:$B$1000=H$5)*(DB!$C$4:$C$1000=I$5)*(DB!$D$4:$D$1000=$H8)),DB!$F$4:$F$1000),"")

Sheet: FP

[pcgk33]

thank you very much! it is very useful!

[AliGW]

You're welcome!

If that takes care of your original question, please select Thread Tools from the menu link above and mark this thread as SOLVED. Thanks.

[pcgk33]

I finally get to learn =aggregate now, thank you very much! masterpiece.

[AliGW]

Bear in mind it only works in newer versions of Excel: https://support.office.com/en-us/art...6-e19993fa26df