Find Names and list that meet specific criteria

[ncorde]

I've done a lot of searching and could really use some help on this one. (see image below)

I have tiers that I need to list names in based on the number of items.

Tier 1 = 0-30
Tier 2 = 31-60
Tier 3 = 60+

Based on a table with this info, I'd like it to list the persons based on the number of items.

Based on the image, I'd like excel to return the following:

Example.JPG

Tier 1
Beth
Simon

Tier 2
Brandon
Chris
Destiny

Tier 3
John
Joe
Sally

I can't figure this one out for the life of me. Help

[kersplash]

You could use a new column that uses a formula to determine the Tier.

Then use a pivot table to display your output.

[ncorde]

I would be fine with a new column but that’s where I get lost. What formula to use. I’m assuming it would be an IF formula?

[AliGW]

Will you please attach a sample Excel workbook? We are not able to work with or manipulate a picture of one and nobody wants to have to recreate your data from scratch.

1. Make sure that your sample data are REPRESENTATIVE of your real data. The use of unrepresentative data is very frustrating and can lead to long delays in reaching a solution.

2. Make sure that your desired results are also shown (mock up the results manually).

3. Make sure that all confidential data is removed or replaced with dummy data first (e.g. names, addresses, E-mails, etc.).

4. Try to avoid using merged cells as they cause lots of problems.

Unfortunately the attachment icon doesn't work at the moment, so to attach an Excel file you have to do the following: just before posting, scroll down to Go Advanced and then scroll down to Manage Attachments. Now follow the instructions at the top of that screen.

Please pay particular attention to point 2 (above): without an idea of your intended outcomes, it is often very difficult to offer appropriate advice.

[FDibbins]

A sample file is almost always better, saves us from reconstructing your data, but I felt like some typing practice, so...

	Q	R	S
1	Name	%	Qty
2	aa		90
3	bb		119
4	cc		45
5	dd		60
6	ee		21
7	ff		5
8	gg		34
9	hh		59
10
11
12	Tier 1	Tier 2	Tier 3
13	ee	cc	aa
14	ff	dd	bb
15		gg
16		hh

Q13=IFERROR(INDEX($Q$2:$Q$9,SMALL(IF($S$2:$S$9<=30,ROW($Q$2:$Q$9)-1),ROWS($A$1:A1))),"")
R13=IFERROR(INDEX($Q$2:$Q$9,SMALL(IF(($S$2:$S$9>30)*($S$2:$S$9<=60),ROW($Q$2:$Q$9)-1),ROWS($A$1:A1))),"")
S13=IFERROR(INDEX($Q$2:$Q$9,SMALL(IF($S$2:$S$9>60,ROW($Q$2:$Q$9)-1),ROWS($A$1:A1))),"")
these are all ARRAY formulas ...confirmed by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. You will know the array is active when you see curly braces { } appear around your formula. If you do not CTRL+SHIFT+ENTER you will get an error or a clearly incorrect answer.

After you enter all 3, copy them down as needed

[ncorde]

A sample file is almost always better, saves us from reconstructing your data, but I felt like some typing practice, so...

	Q	R	S
1	Name	%	Qty
2	aa		90
3	bb		119
4	cc		45
5	dd		60
6	ee		21
7	ff		5
8	gg		34
9	hh		59
10
11
12	Tier 1	Tier 2	Tier 3
13	ee	cc	aa
14	ff	dd	bb
15		gg
16		hh

Q13=IFERROR(INDEX($Q$2:$Q$9,SMALL(IF($S$2:$S$9<=30,ROW($Q$2:$Q$9)-1),ROWS($A$1:A1))),"")
R13=IFERROR(INDEX($Q$2:$Q$9,SMALL(IF(($S$2:$S$9>30)*($S$2:$S$9<=60),ROW($Q$2:$Q$9)-1),ROWS($A$1:A1))),"")
S13=IFERROR(INDEX($Q$2:$Q$9,SMALL(IF($S$2:$S$9>60,ROW($Q$2:$Q$9)-1),ROWS($A$1:A1))),"")
these are all ARRAY formulas ...confirmed by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. You will know the array is active when you see curly braces { } appear around your formula. If you do not CTRL+SHIFT+ENTER you will get an error or a clearly incorrect answer.

After you enter all 3, copy them down as needed

You're my hero! Thank you! That worked! Will mark as solved!

[FDibbins]

Happy to help and thanks for the kind words

For future reference, consider attaching a sample file, and also, there is no need to quote whole posts -- it's just clutter. If you are responding to a post out of sequence, limit quoted content to a few relevant lines that makes clear to whom and what you are responding

For normal conversational replies, try using the QUICK REPLY box below.