would this be a nested IF?

I'm sure it could be done with a nested IF() function, but I would be more inclined to build a lookup table and use a 2D lookup function (see "lookup and reference functions here": https://support.office.com/en-us/art...rs=en-US&ad=US ).

1) Build lookup table exactly like you have attempted in your post.
2) A MATCH() function to find "group #" in the left most column of the lookup table. MATCH(B2,absolute_reference_to_left_column_of_lookup_table,0)
3) A MATCH() function to find the "territory #" in the top row of the lookup table. MATCH(C2,absolute_reference_to_top_row_of_lookup_table,0)
4) An INDEX() function using the main body of the lookup table and the results of 2 and 3 to extract the desired value. =INDEX(absolute_reference_to_body_of_lookup_table,result_of_step_2,result_of_step_3).
5) Nest that inside of your "splitting" formula(s) to get the final result.

That's how I'd probably do something like this. Will something like that work for you?

If that is your concern, remember that MATCH() functions can easily be nested inside of INDEX() functions =restofsplitfunction*INDEX(body of table, MATCH(group #,left column,0),MATCH(terr #,top row,0)) (assuming multiplication is the correct operation).

I don't use named ranges/tables much, so I am not exactly sure how it would look where you name the entire lookup table. If you have three separate named ranges:
Group_col that refers to the leftmost "group #" column of the lookup table (not including the first row of that column). For example, maybe this is M3:M8.
Terr_row that refers to the top row of the lookup table (not including the first column of that row). For example, maybe this is N2:O2.
lookup_body that refers to the main body of the table (not including the first row or first column -- just the block of return values). For example, this might be N3:O8

The lookup function might look like =INDEX(lookup_body,MATCH(B2,Group_col,0),MATCH(C2,Terr_row,0))
or, without the named ranges =INDEX($N$3:$O$8,MATCH(B2,$M$3:$M$8,0),MATCH(C2,$N$2:$O$2,0))

I'm not sure what trouble you are having with the lookup table. Here's what I had in mind. You could easily hide the columns with the lookup table or move the lookup table (L3:N9) to its own tab, maybe even hide that tab, whatever you feel you need to do. Also note that I did not know the full calculation you wanted in column F, so I just did the lookup.

Now I think I am completely confused.

then the outcome is the corresponding row column of Column E (Total Space Available) * relevant percentage, ), 1/6 or 1/3 rd of total space available

This sound like column F should be as simple as multiplying the current formula in F by E. =E2*INDEX($M$4:$N$9,MATCH(B2,$L$4:$L$9,0),MATCH(C2,$M$3:$N$3,0)). However, in post 13, you use 0, 1, or 2 as the multiplier, and I don't know where the 0, 1, or 2 came from (unless they just represent the ratio of those percentages 0/6, 1/6, 2/6).

As I said, I expect it is possible with a long nested IF() function, but I thought that this lookup table approach would be easier than a long nested IF().

Try this in F2, copied down:

=IFERROR(E2/IF(C2="Terr 1",LOOKUP(1000, SEARCH({"One","Two","Three","Four","Five","Six"},B2),{3,3,0,6,6,0}),IF(C2="Terr 2",LOOKUP(1000,SEARCH({"One","Two","Three","Four","Five","Six"},B2),{3,6,6,6,6,0}),"")),0)

Just noticed that you are using Excel 2003...

=IF(B2="","",E2/IF(C2="Terr 1",LOOKUP(1000,SEARCH({"One","Two","Three","Four","Five","Six"},B2),{3,3,0,6,6,0}),IF(C2="Terr 2",LOOKUP(1000,SEARCH({"One","Two","Three","Four","Five","Six"},B2),{3,6,6,6,6,0}),"")))

or
F2=IF(B2="","",E2/SUMPRODUCT(({"One","Two","Three","Four","Five","Six"}=B2)*IF(C2="Terr 1",{3,3,0,6,6,0},{3,6,6,6,6,0})))
Try this and copy towards down