Maximum value by time criteria

[amir0914]

Hi all, I need a function to find maximum value of Count column between Name criteria and between two time criteria, as the same of below image :

Attachment 662090

Thanks in advanced.

[benishiryo]

try this array formula:
=MAX(IF($A$2:$A$33=G2,IF($B$2:$B$33>=H2,IF($B$2:$B$33<=I2,$B$2:$B$33))))

...confirmed by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. You will know the array is active when you see curly braces { } appear around your formula. If you do not CTRL+SHIFT+ENTER you will get an error or a clearly incorrect answer.

[davsth]

Also an array (shift control enter) but slightly shorter
=MAX(($A$2:$A$33=G2)*($c$2:$c$33>=H2)*($c$2:$c$33<=I2)*($B$2:$B$33))

[6StringJazzer]

Attachment 662090

I am not sure if this attachment is your image or a file but it is not valid. If you intended to upload a file please follow the instructions in the yellow banner at the top of the page.

[amir0914]

Thanks to benishiryo, your code is working well, Can you also write functons to rnage K1 and L1 for extract first and last item by the same criteria.
For example for "A1" value in Name field by time criteria, the first value of column Count is "1" and last value is "4". I also have uploaded the sample file. thanks to 6StringJazzer for your guidance.

[benishiryo]

you probably addressed the wrong person. you used davsth's formula.

an array formula for K2:
=INDEX($B$2:$B$33,MIN(IF($A$2:$A$33=G2,IF($C$2:$C$33>=H2,IF($C$2:$C$33<=I2,ROW($C$2:$C$33)))))-ROW($C$2)+1)

and for L2:
=LOOKUP(2,1/(($A$2:$A$33=G2)*($C$2:$C$33>=H2)*($C$2:$C$33<=I2)),$B$2:$B$33)

[davsth]

for l2 I wold do the same

for k2 as an array, either
=INDEX($B$2:$B$33,MIN(IF(($A$2:$A$33=G2)*($C$2:$C$33>=H2)*($C$2:$C$33<=I2),ROW($C$1:$C$32))))

or

=INDEX($B$1:$B$33,MIN(IF(($A$2:$A$33=G2)*($C$2:$C$33>=H2)*($C$2:$C$33<=I2),ROW($C$2:$C$33))))

[amir0914]

THank you both, your codes work perfect, I want to type time value manually, but it's not working : (time value replaced with H2 range in above code)

=MAX(($A$2:$A$33=G2)*($c$2:$c$33>="09:00:01")*($c$2:$c$33<=I2)*($B$2:$B$33))

Why doesn't time value work right?

[AliGW]

That is text. See if this works:

=MAX(($A$2:$A$33=G2)*($C$2:$C$33>=TIME(9,0,1))*($C$2:$C$33<=I2)*($B$2:$B$33))

[AliGW]

Thanks for the rep.

If that takes care of your original question, please select Thread Tools from the menu link above and mark this thread as SOLVED.

[amir0914]

Thany you AliGW, But my problem hasn't resolved yet, I have another question, I want to put date instead time, is this right :

=MAX(($A$2:$A$33=G2)*($C$2:$C$33>=date(01/05/2016))*($C$2:$C$33<=date(04/05/2016))*($B$2:$B$33))

Thanks in advanced.

[CARACALLA]

Attach file for new question

[AliGW]

The date bit needs to look like this:

DATE(2016,5,1)

[amir0914]

Thank you AliGW, you did great.

[AliGW]

If that takes care of your original question, please select Thread Tools from the menu link above and mark this thread as SOLVED.