Good day! I am working on a shipping company as a low level entry. Given the data in the attached spreadsheet, I need to get the average annualise tonnage per ship. Is this even possible? Can someone help me please.
Good day! I am working on a shipping company as a low level entry. Given the data in the attached spreadsheet, I need to get the average annualise tonnage per ship. Is this even possible? Can someone help me please.
Welcome.
Formula for M2 and then fill down =SUMPRODUCT(--(YEAR($B$2:$B$23)=L2)*$G$2:$G$23)
Formula for N2 and then fill down =SUMPRODUCT(--(YEAR($B$2:$B$23)=L2)*$E$2:$E$23)
My General Rules if you want my help. Not aimed at any person in particular:
1. Please Make Requests not demands, none of us get paid here.
2. Check back on your post regularly. I will not return to a post after 4 days.
If it is not important to you then it definitely is not important to me.
Thanks for the response mehmetcik. I tried the formula and it gave me the same results as when I just used SUM. Am I doing it wrong?
M2=SUMPRODUCT((YEAR($B$2:$B$23)=$L2)*($G$2:$G$23))/SUMPRODUCT(--(YEAR($B$2:$B$23)=$L2))
copy down
N2=SUMPRODUCT((YEAR($B$2:$B$23)=$L2)*($E$2:$E$23))/SUMPRODUCT(--(YEAR(B$2:B$23)=$L2))
copy down
Please try at
M2
=AVERAGEIFS($G$2:$G$23,$B$2:$B$23,">"&DATE(L2,1,0),$B$2:$B$23,"<"&DATE(L2+1,1,1))
N2
=AVERAGEIFS($E$2:$E$999,$B$2:$B$999,">"&DATE(L2,1,0),$B$2:$B$999,"<"&DATE(L2+1,1,1))
I believe the average annualized tonnage per ship is:
=J2*SUM(G2:G23)/SUM(E2:E23)
To understand why, consider: for each ship, how would we calculate the annualized tonnage?
Starting in H2, that would be =$J$2*G2/E2.
Then ostensibly, the average annualized tonnage per ship might be =AVERAGE(H2:H23).
But mathematically, the "average of the parts" (averages or ratios), calculated by the AVERAGE formula, is not the same as the average of the whole, in general.
So the first formula above is the sum of the tonnage divided by the sum of the hours (average tonnage per hour), multiplied by hours per year (annualized).
-----
However, that assumes that you want to consider only the unloading hours. It does not include the time at berth before unloading.
That does seem correct, based on your other statistics, which only take unloading hours into account.
But on the off-chance that you want to account for total time at berth, you might add another column for total time at berth per ship: =24*(D2-B2).
Then adapt the first formula above accordingly; that is, refer to the new column instead of column E.
Or you can use the following formula:
=J2 * SUM(G2:G23)/(24*SUMPRODUCT(D2:D23-B2:B23))
or
=J2 * SUM(G2:G23)/SUMPRODUCT(D2:D23-B2:B23)/24
The two formulas are equivalent mathematically. I think the last formula is easier to read.
Last edited by joeu2004; 04-06-2020 at 04:10 PM.
Apologies. I got distracted.
Try this formula in O2 =SUMPRODUCT(--(YEAR($B$2:$B$23)=L2)*$G$2:$G$23)/SUMPRODUCT(--(YEAR($B$2:$B$23)=L2))
Thank you everyone who replied most especially, thanks for the explanation on how the the formula works joeu2004.
Please note I have no prior experience to complicated formulas in excel thus my username to be newbie. Today I was asked to add the year to date annualised rate. Added in column I is the unloading rate. I used the formula to get the year to date rate but the numbers seem to be too low. PLEASE PLEASE can you help me?
Your questions have more to do with math than with Excel. And even more to do with the definition of terms, which is unclear.
First, how did you calculate column I?
I would expect =G2/E2 in I2. But that results in 142.053554228479, not 179.678362573099, which you have as a constant (copy-and-paste-value).
Second, the term "year-to-date" annualized rate is unclear. What year; and to what date?
Your calculation is even less clear. If I2 is tonnage per hour, then I2*E2 is tonnage. And I2*E2/L2 is tonnage per hour in a year. That is neither "year-to-date", not "annualized".
Off-hand, the only sense that I can make of "year-to-date annualized rate" is the formula that I provide in response #8, specifically for 2020.
That is, "year-to-date" usually means __current__ year to __current__ date (in the same year). So: (sum of tonnage for 2020) / (sum of unloading hours for 2020) times work-hours per year:
=$L2*O4/P4
If you do not understand the mathematical calculation that is being asked of you, I suggest that you get clarification by example.
It is impossible (or foolish) to write the Excel formula without understanding the math. GIGO!
sorry about that. the value in column I came from a different report made by another person at work but supposedly the results in these 2 reports should match. please disregard the values I placed in column I. the results in column I should be equal to G/E.
we are supposed to be unloading at a minimum of 3 million tonnes/year and the main idea of getting the "year to date annualized rate" is to see whether we are on track on achieving that goal by end of 2020 or not.
Last edited by newbie540; 04-07-2020 at 12:56 PM.
Good input! Based on that, I believe the formula that I provided in #10 does just that.
It is about 3.8M. But if it were under 3M, it tells you that you need to unload tonnage in fewer hours; that is, increase the crews or work more efficiently. Alternatively, increase the rate at which ships and tonnage arrives; presumably not under your control.
In contrast, the other formulas calculated tonnage per year. That might tell you that you need more tonnage per ships and/or more ships. Again, probably not under your control.
Finally, you can fine-tune your formulas, similar to the suggestion in mehmetcik's response #2 (improved), to wit:
O2: =SUMPRODUCT(--(YEAR($C$2:$C$23)=N2), $G$2:$G$23)
P2: =SUMPRODUCT(--(YEAR($C$2:$C$23)=N2), $E$2:$E$23)
Note the use of comma (","), not multiplication ("*").
Alternatively, you could write (YEAR($C$2:$C$23)=N2)*$G$2:$G$23. But there is no need to use both double-negate ("--") and multiplication ("*").
There are currently 1 users browsing this thread. (0 members and 1 guests)
Bookmarks