Automatic accumulated sum when changing month

[Lutti92]

Hi all,
Semi-noob at Excel here, hoping someone can help I have a monthly sales report that I would looove to make a bit more automatic than it currently is. At the moment, I have to update 2 columns manually each month because it has to sum X amount of cells for the accumulated sales up to and including the month I'm reporting on. Is there any way to make it automatically sum up to and including the month I type in the top? It was fairly easy to do for the 1 month I'm reporting on because it just looks for the month and returns the amount for that one month, but I can't figure out how to make it calculate the accumulated YTD amount when I type in a new month
I hope the attachment works to show I've taken a small snip of the report and put in some random figures for 2022 just to see if I could get it to work Thank you all in advance!

P.S. I should mention that I'm looking to avoid any extra columns or matrixes if at all possible. The "real" workfile is already massive enough as it is (400 rows and A to CO in columns at the moment, plus 3 additional sheets that it pulls data from and these sheets each have around 8000 rows each!)

[AliGW]

If you change your text labels (2022, March) to actual dates, this becomes much simpler. Bear in mind they can still be DISPLAYED as you wish. Interested?

[Lutti92]

Anything to get this working What it says in the top doesn't matter too much as long as my superiors can fairly easily tell whether the report is for March or May and whether the column is for 2021 or 2022, then it's fine

[AliGW]

OK.

In F2:

=DATEVALUE("01/01/"&F1)

In G2 copied across to Q2:

=EDATE(F2,1)

In S2 copied across to AD2:

=EDATE(F2,-12)

In A2:

01/03/2021

In B2:

=EDATE(A2,12)

All of the above need to be set to custom formmatting: mmmm

In C2:

=CONCATENATE("YTD ",TEXT(A2,"mmmm"))

In D2:

=C2

In A5:

=SUMIFS($F5:$AD5,$F$2:$AD$2,A$2)

In B5:

=SUMIFS($F5:$AD5,$F$2:$AD$2,B$2)

In C5:

=SUMIFS($F5:$AD5,$F$2:$AD$2,"<="&A$2,$F$1:$AD$1,A$1)

In D5:

=SUMIFS($F5:$AD5,$F$2:$AD$2,"<="&B$2,$F$1:$AD$1,B$1)

Your Danish locale will require some tweaks to the above, so PLEASE refer to the attachment!

[Lutti92]

Thank you so so much! This works absolutely perfect and I've learned loads of new things! Very much appreciated

[AliGW]

As a retired teacher, I'll take that!!!

Thanks for the kind rep comments.