Age Forumla using Date of Birth - Excel 2010

[SaleenaKhan]

I am creating a form using Excel 2010, the individuals using this form will be required to input their date of birth.
I used the following formula to calculate their age -


=IF(MONTH(TODAY())>MONTH(C13),YEAR(TODAY())-YEAR(C13),
IF(AND(MONTH(TODAY())=MONTH(C13),DAY(TODAY())>=DAY(C13)),
YEAR(TODAY())-YEAR(C13),(YEAR(TODAY())-YEAR(C13))-1))

This formula has worked perfectly, however the default age is 113 and is displayed within the cell when the date of birth has not been entered.
My question is that, is there a way to make the default age not visible when the date of birth is not entered? If so, how?

[Andrew-R]

How about:

=IF(C13="","",DATEDIF(C13,TODAY(),"y"))

[Pete_UK]

Try this:

=IF(C13="","",IF(MONTH(TODAY())>MONTH(C13),YEAR(TODAY())-YEAR(C13),
IF(AND(MONTH(TODAY())=MONTH(C13),DAY(TODAY())>=DAY(C13)),
YEAR(TODAY())-YEAR(C13),(YEAR(TODAY())-YEAR(C13))-1)))

Changes shown in red. There are other ways of calculating age from date of birth using the DATEDIF function, for example.:

=IF(C13="","",DATEDIF(C13,TODAY(),"y")&" years "&DATEDIF(C13,TODAY(),"ym")&" months "&DATEDIF(C13,TODAY(),"md") &" days")

Hope this helps.

Pete

[SaleenaKhan]

Thank you for your responses

[SaleenaKhan]

How about:

=IF(C13="","",DATEDIF(C13,TODAY(),"y"))

Thank you for your help, however I need that formula in particular

[SaleenaKhan]

Try this:

=IF(C13="","",IF(MONTH(TODAY())>MONTH(C13),YEAR(TODAY())-YEAR(C13),
IF(AND(MONTH(TODAY())=MONTH(C13),DAY(TODAY())>=DAY(C13)),
YEAR(TODAY())-YEAR(C13),(YEAR(TODAY())-YEAR(C13))-1)))

Changes shown in red. There are other ways of calculating age from date of birth using the DATEDIF function, for example.:

=IF(C13="","",DATEDIF(C13,TODAY(),"y")&" years "&DATEDIF(C13,TODAY(),"ym")&" months "&DATEDIF(C13,TODAY(),"md") &" days")

Hope this helps.

Pete

Thank you ever so much, I used to corrected formula and it worked wonders