Sum multiple COUNTIF statements in a single formula

[bfs3]

I am working with an attendance sheet, and I am trying to calculate whether a particular person attended either of the two sessions on Friday (Session 1 is Column B and Sessions 2 is column C) and either of the two sessions on Saturday (Sessions 1 is Column E and Session 2 is Column E).

I have written a formula that assigns a value of 1 if the person attends at least 1 session on both Friday and Saturday:
=IF(SUM(IF(COUNTIF(B3:C3, "x")>=1, 1, 0)+IF(COUNTIF(D3:E3, "x")>=1, 1, 0))=2, 1, 0)

In a single formula, how would I sum all those formulas for rows 3 to 10, for example? (I presume some sort of sum/sumproduct formula)

I've attached a workbook if that's helpful.

Thanks in advance,

Ben

[FDibbins]

Maybe this?
F3, copied down....
=IF(COUNTIF(B3:C3, "x")>=1, 1, 0)+IF(COUNTIF(D3:E3, "x")>=1, 1, 0)
I9=COUNTIF(F3:F6,2)

[bfs3]

Thanks for your response, Ford. I am actually trying to calculate the value with just 1 formula on the page if that's possible.

I am basically trying to write a formula that does:

=IF(COUNTIF(B3:C3, "x")>=1, 1, 0)+IF(COUNTIF(D3:E3, "x")>=1, 1, 0) +
IF(COUNTIF(B4:C4, "x")>=1, 1, 0)+IF(COUNTIF(D4:E4, "x")>=1, 1, 0) +
IF(COUNTIF(B5:C5, "x")>=1, 1, 0)+IF(COUNTIF(D5:E5, "x")>=1, 1, 0) +
IF(COUNTIF(B6:C6, "x")>=1, 1, 0)+IF(COUNTIF(D6:E6, "x")>=1, 1, 0) +
IF(COUNTIF(B7:C7, "x")>=1, 1, 0)+IF(COUNTIF(D7:E7, "x")>=1, 1, 0) +
IF(COUNTIF(B8:C8, "x")>=1, 1, 0)+IF(COUNTIF(D8:E8, "x")>=1, 1, 0) +
etc., etc.

I would like to sum all the rows if possible, but at the very least to row 250! I hope that clarifies my question / the solution I am looking for.

[daddylonglegs]

I would like to sum all the rows if possible, but at the very least to row 250!

Try this formula

=SUMPRODUCT(((B3:B250="x")+(C3:C250="x")>0)+0)+SUMPRODUCT(((D3:D250="x")+(E3:E250="x")>0)+0)

edit: that's based on your last post where you seem to be counting 1 for every pair of cells - if you want to count rows only if both pairs of cells in each row have at least one "x" (i.e. to get 2 in your example) then that would be this version

=SUMPRODUCT(((B3:B250="x")+(C3:C250="x")>0)*((D3:D250="x")+(E3:E250="x")>0))

You can expand it for any number of rows

[bfs3]

Thanks, daddylonglegs. Formula works great.