footbal match,count tips

[cisilej2]

First, my english is not so good,I'll try to write my problem. I have excel file which made thanks to help from another forum. I want to fill tips from me and my friends for football(soccer) matches. Present version of file calculate how much everybody get points. If you get correct score, you get 3 points, if you hit who is winner but don't hit correct score, you get 1 point. ( if match finish with 2-1 for Team A against Team B, and I was bet on that result will be 3-1,I'll get 1 point, if match finish with 2-1 ,I'll get 3 point) That situation is in file which I uploaded. Now, I want to add option for 2 points. It will be if match finish with 2-1 for Team A against Team B and I bet on to result be 3-2,4-3,5-4 etc for Team A .
There is another complication, for draw result. I want that 2 points get if match finish with 2-2 and I bet on result to be 1-1 or 3-3, and 1 point if match over 0-0, 4-4,5-5,6-6 etc. can somebody help me?

[K m]

You need to breakdown the options:
Assuming your guess is in cell A1 and B1 and the results are in cells C1 and D1

For Example:
Team X Score 3-1 where the 3 is in cell A1 and the 1 is in cell B1
and the result is 3-1 in cells C1 and D1

The first part, award 3 points: {You got the correct score and winner}
=IF(AND(A1=C1,B1=D1),3,

The second part, award 2 points: {You got the correct winner and the same score difference but not the correct score }
IF(OR(AND(A1>B1,C1>D1,ABS(A1-B1)=ABS(C1-D1)),AND(B1>A1,D1>C1,ABS(A1-B1)=ABS(C1-D1))),2,

The third part, award 1 point: {You got the correct winner}
IF(OR(AND(A1>C1,B1>D1),AND(C1>A1,D1>B1)),1,0

Put it together, the formula becomes:
=IF(AND(A1=C1,B1=D1),3,
IF(OR(AND(A1>B1,C1>D1,ABS(A1-B1)=ABS(C1-D1)),AND(B1>A1,D1>C1,ABS(A1-B1)=ABS(C1-D1))),2,
IF(OR(AND(A1>C1,B1>D1),AND(C1>A1,D1>B1)),1,0)))

[cisilej2]

K m, thanks very,very much for helping. There is a little error, if you can check. It is related on draw results. This doesn't calculate 2 points as I wanted. It only calculate values 3 and 1 points, not 2 points.
Once again, thanks for this, it is very useful for me.

[K m]

I relooked at the formula try this formula:

=IF(AND(A2=C2,B2=D2),3,IF(OR(AND(A2>B2,C2>D2,ABS(A2-B2)=ABS(C2-D2)),OR(AND(B2>A2,D2>C2,ABS(A2-B2)=ABS(C2-D2)),AND(A2=B2,C2=D2,ABS(A2-C2)=1))),2,IF(OR(AND(A2>B2,C2>D2),AND(B2>A2,D2>C2),AND(A2=B2,C2=D2,ABS(A2-C2)<>1)),1,0)))

I have included an example spreadsheet

[cisilej2]

Thank you very much for helping and for your working.It works perfectly. I have also got another solution on another forum, there is formula:
= IF((COUNT(D;G)<2);0;
IF((D=d1)*(G=g1);3;(SIGN(D-G)=SIGN(d1-g1))+((D-G)=(d1-g1))-(D=G)*(d1=g1)*(ABS(D-d1)>1))

D-home goals
G-visitor goals
d1-my home tip
g1-my visitor tip

This part "COUNT(D;G)<2);0;" is for aesthetic reasons. When I put all my tips for 96 matches, without this part of code, I would get 3 points where I put 0-0, I would get 2 points where I put 1-1 and I would get 1 points where I put 3-3, 4-4 etc. and before competition starts.

K m, thanks for help !!!