Compile list based on drop-down menu pick

**Excel white-belt** · 10-16-2012, 01:15 PM

I would like to report data from one area of my worksheet into other separate areas of the worksheet based on the value of a drop-down menu pick. I don't want to move the data, just compile separate lists that report the data. I have attached an example to illustrate what I am looking for. Lastly, the original data has to remain unchanged and unsorted, since other users will be adding and removing lines from this list, and its order must be preserved.

There is probably an easy way to do this, I just don't know what it is. Thanks!

Sorting list example.xlsx

**ChemistB** · 10-16-2012, 03:29 PM

Not sure exactly what you are looking for but this will separate your data into the 3 lists.
1. In E10 dragged down
=D10&COUNTIF($D$10:D10,D10)
This gives you unique identifiers for each list. You can hide this column if you like

2. In G6 dragged down

=IF(COUNTIF($D$10:$D$21,"A")>=ROW(A1),INDEX($B$10:$B$21,MATCH("A"&ROW(A1),$E$10:$E$21,0)),"")

The COUNTIF> ROW(1) just counts how many are in list A and as you drag that down, it'll put blanks ("")
INDEX(.... returns a value from Col B that is the same # of rows down as "A" &ROW(A1) or "A1"

3. In H6 dragged down
=IF(COUNTIF($D$10:$D$21,"A")>=ROW(A1),INDEX($C$10:$C$21,MATCH("A"&ROW(A1),$E$10:$E$21,0)),"")
same as above except looking at Col C

The equations in the other tables are similar.

Questions?

**Excel white-belt** · 10-17-2012, 08:43 AM

Thanks! That is precisely what I am looking for. Just out of curiosity, did you use "ROW(A1)" because it was blank? The COUNTIF is counting every cell in the range that is greater than the blank cell A1, right?

**ChemistB** · 10-17-2012, 09:19 AM

Nope, it works like this
(COUNTIF($D$10:$D$21,"A")>=ROW(A1)
COUNTIF counts every cell in D10:D20 that equals A. That's a constant
ROW(A1) = 1. However, since I didn't apply an anchor (i.e $A$1) it changes as we copy it down so ROW(A2) = 2 and so forth

=IF(COUNTIF($D$10:$D$21,"A")>=ROW(A1),INDEX($B$10:$B$21,MATCH("A"&ROW(A1),$E$10:$E$21,0)),"")
So as soon as the ROW portion becomes greater than the # of "A's" in your range, it starts to populate your cell with blanks ("")
This is done to prevent errors when applying your INDEX formula.
Did that answer your question?

**Excel white-belt** · 10-17-2012, 09:37 AM

Yep, thanks for the lesson, I appreciate it!

**Cutter** · 10-17-2012, 06:54 PM

@ Excel white-belt

Welcome to the forum.

Based on your last post it seems that you are satisfied with the solution(s) you've received but you haven't marked your thread as SOLVED. I'll do that for you now but please keep in mind for your future threads that Rule #9 requires you to do that yourself. If your problem has not been solved you can use Thread Tools (located above your first post) and choose "Mark this thread as unsolved".
Thanks.

Also, as a new member of the forum, you may not be aware that you can thank those who have helped you by clicking the small star icon located in the lower left corner of the post in which the help was given. By doing so you can add to the reputation(s) of those who helped.