Trying to find a formula to find a random $ amount in a text in a cell

**Miki1** · 01-28-2013, 09:07 PM

I have a string of text and there is either one or two dollar amounts within the text. I'd like to be able to pull those dollar amounts into another cell. The location within the cell varies and the dollar amounts vary. Example:

$125.95 a month, for a savings of $22.00 a month

and/or

Sales within a month is $130 a month for the month of January

Is there something that could find $ and pull the amounts in the next one and/or two cells?

Any help would be most appreciated. Thank you.

**Pete_UK** · 01-28-2013, 09:51 PM

Suppose you have those two phrases in A1 and A2. Then you can put this formula in B1 to get the first number:

Formula:

=IF(ISNUMBER(FIND("$",A1)),--MID(SUBSTITUTE(A1," ",REPT(" ",10)),FIND("$",SUBSTITUTE(A1," ",REPT(" ",10)))+1,10),"")

Copy it down column B for as many phrases that you have.

Put this formula in C1 to get the second number (if it exists):

Formula:

=IF(AND(ISNUMBER(FIND("$",A1)),LEN(A1)-LEN(SUBSTITUTE(A1,"$",""))>1),--MID(SUBSTITUTE(A1," ",REPT(" ",10)),FIND("$",SUBSTITUTE(A1," ",REPT(" ",10)),FIND("$",SUBSTITUTE(A1," ",REPT(" ",10)))+1)+1,10),"")

and again, copy down as required.

Hope this helps.

Pete

**Miki1** · 01-28-2013, 10:02 PM

Hi Pete,
Thank you. AWESOME! It works perfect! You have saved me soooo much time. Thank you.

**vlady** · 01-28-2013, 10:13 PM

Based on your last post it seems that you are satisfied with the solution(s) you've received but you haven't marked your thread as "SOLVED".

How to mark a thread Solved
Go to the first post
Click edit
Click Go Advanced
Just below the word Title you will see a dropdown with the word No prefix.
Change to Solved
Click Save

Note:
You can also thank those who have helped you by clicking the small star icon located in the lower left corner of the post in which the help was given.
By doing so you can add to the reputation(s) of those who helped and shared their time in helping you.