SUMIFS Multiple Criteria Same Column

**jsharrard** · 07-01-2013, 02:05 PM

I'm trying to use SUMIFS in Excel 2007 as follows to evaluate multiple criteria within the same column.

=SUMIFS('September Orders'!$H:$H,'September Orders'!$F:$F,'Individual Agency Report'!$E$2,'September Orders'!$P:$P,{"16*","30*"},'September Orders'!$C:$C,"<>*CSFP*")

This formula should work fine, I think--but the section in bold returns the sum only for the first criteria listed in column P--such that September Orders'!$P:$P,{"16*","30*"} returns the same tally as if the formula were September Orders'!$P:$P,"16*" and September Orders'!$P:$P,{30*","16*"} returns as if it were September Orders'!$P:$P"30*".

The solution using the {bracketing} came originally from Daddy LongLegs on this post: http://www.excelforum.com/excel-form...ne-column.html

**Jonmo1** · 07-01-2013, 02:10 PM

Are you trying to do this as an OR criteria...If column P = 16* OR 30*

Wrap it in a regular sum function.

=SUM(SUMIFS(.....))

**jsharrard** · 07-01-2013, 03:00 PM

To do this would involve an inordinate amount of revision of the current spreadsheet--rewriting formulae across ~18 worksheets; whereas if the {bracketing} solution could be tweaked to work, the formulae could be resolved with a simple Ctrl+H/ Replace All

**Jonmo1** · 07-01-2013, 03:05 PM

I'm not saying

=SUM(SUMIFS(...),SUMIFS(...))

I'm Saying
=SUM(SUMIFS(...))
Where SUMIFS(...) is the formula you posted

=SUM(SUMIFS('September Orders'!$H:$H,'September Orders'!$F:$F,'Individual Agency Report'!$E$2,'September Orders'!$P:$P,{"16*","30*"},'September Orders'!$C:$C,"<>*CSFP*"))

**daddylonglegs** · 07-01-2013, 03:31 PM

Just to back up what Jonmo says.....

In the thread you linked to the formula I suggested was

=SUM(SUMIFS(Table1[ColB],Table1[ColA],{"DOG","CAT"}))

Notice the SUM around the SUMIFS - the original formula returns an "array" of values (one for each element of {"16*","30*"} or {"dog","cat"}), so you need another function like SUM to sum that array and get the total you need.

**jsharrard** · 07-01-2013, 04:35 PM

Many thanks!

**bgru** · 08-18-2017, 04:29 PM

Hi All,

I've encountered this issue and the sum seemed to work but I realized it was working only for the 1st value in my brackets, not the 2nd, unless I do ctrl+shift+enter which doesn't make sense since Excel should just do the sum.

Here is the formula =SUM(SUMIFS(OnHand!C:C,OnHand!A:A,L24285,OnHand!G:G,IF(R24285="GRD",{"A","A+"},VLOOKUP(R24285,Info!U:V,2,FALSE))))

The odd thing is if I highlight the inside of the sum function I get the expected array result: =SUM({0,9}) and clicking enter at this point provides the correct result but I don't understand why its not just working.

My system is up to date, does anyone know if there's a setting that might be causing the issue, or perhaps the fact that its across tabs is an issue?

Thanks

**AliGW** · 08-18-2017, 05:08 PM

Unfortunately your post does not comply with Rule 2 of our Forum RULES. Do not post a question in the thread of another member -- start your own thread.

If you feel an existing thread is particularly relevant to your need, provide a link to the other thread in your new thread.

Old threads are often only monitored by the original participants. New threads not only open you up to all possible participants again, they typically get faster response, too.