+ Reply to Thread
Results 1 to 8 of 8

SUMIFS Multiple Criteria Same Column

  1. #1
    Registered User
    Join Date
    07-01-2013
    Location
    Pittsburgh, PA
    MS-Off Ver
    Excel 2007
    Posts
    7

    SUMIFS Multiple Criteria Same Column

    I'm trying to use SUMIFS in Excel 2007 as follows to evaluate multiple criteria within the same column.

    =SUMIFS('September Orders'!$H:$H,'September Orders'!$F:$F,'Individual Agency Report'!$E$2,'September Orders'!$P:$P,{"16*","30*"},'September Orders'!$C:$C,"<>*CSFP*")

    This formula should work fine, I think--but the section in bold returns the sum only for the first criteria listed in column P--such that September Orders'!$P:$P,{"16*","30*"} returns the same tally as if the formula were September Orders'!$P:$P,"16*" and September Orders'!$P:$P,{30*","16*"} returns as if it were September Orders'!$P:$P"30*".

    The solution using the {bracketing} came originally from Daddy LongLegs on this post: http://www.excelforum.com/excel-form...ne-column.html

  2. #2
    Forum Guru Jonmo1's Avatar
    Join Date
    03-08-2013
    Location
    Bryan, TX
    MS-Off Ver
    Excel 2010
    Posts
    9,763

    Re: SUMIFS Multiple Criteria Same Column

    Are you trying to do this as an OR criteria...If column P = 16* OR 30*

    Wrap it in a regular sum function.

    =SUM(SUMIFS(.....))

  3. #3
    Registered User
    Join Date
    07-01-2013
    Location
    Pittsburgh, PA
    MS-Off Ver
    Excel 2007
    Posts
    7

    Re: SUMIFS Multiple Criteria Same Column

    To do this would involve an inordinate amount of revision of the current spreadsheet--rewriting formulae across ~18 worksheets; whereas if the {bracketing} solution could be tweaked to work, the formulae could be resolved with a simple Ctrl+H/ Replace All

  4. #4
    Forum Guru Jonmo1's Avatar
    Join Date
    03-08-2013
    Location
    Bryan, TX
    MS-Off Ver
    Excel 2010
    Posts
    9,763

    Re: SUMIFS Multiple Criteria Same Column

    I'm not saying

    =SUM(SUMIFS(...),SUMIFS(...))

    I'm Saying
    =SUM(SUMIFS(...))
    Where SUMIFS(...) is the formula you posted

    =SUM(SUMIFS('September Orders'!$H:$H,'September Orders'!$F:$F,'Individual Agency Report'!$E$2,'September Orders'!$P:$P,{"16*","30*"},'September Orders'!$C:$C,"<>*CSFP*"))

  5. #5
    Forum Moderator daddylonglegs's Avatar
    Join Date
    01-14-2006
    Location
    England
    MS-Off Ver
    2016
    Posts
    14,676

    Re: SUMIFS Multiple Criteria Same Column

    Just to back up what Jonmo says.....

    In the thread you linked to the formula I suggested was

    =SUM(SUMIFS(Table1[ColB],Table1[ColA],{"DOG","CAT"}))

    Notice the SUM around the SUMIFS - the original formula returns an "array" of values (one for each element of {"16*","30*"} or {"dog","cat"}), so you need another function like SUM to sum that array and get the total you need.
    Audere est facere

  6. #6
    Registered User
    Join Date
    07-01-2013
    Location
    Pittsburgh, PA
    MS-Off Ver
    Excel 2007
    Posts
    7

    Re: SUMIFS Multiple Criteria Same Column

    Many thanks!

  7. #7
    Registered User
    Join Date
    07-28-2017
    Location
    New Jersey
    MS-Off Ver
    2010
    Posts
    3

    Re: SUMIFS Multiple Criteria Same Column

    Hi All,

    I've encountered this issue and the sum seemed to work but I realized it was working only for the 1st value in my brackets, not the 2nd, unless I do ctrl+shift+enter which doesn't make sense since Excel should just do the sum.

    Here is the formula =SUM(SUMIFS(OnHand!C:C,OnHand!A:A,L24285,OnHand!G:G,IF(R24285="GRD",{"A","A+"},VLOOKUP(R24285,Info!U:V,2,FALSE))))

    The odd thing is if I highlight the inside of the sum function I get the expected array result: =SUM({0,9}) and clicking enter at this point provides the correct result but I don't understand why its not just working.

    My system is up to date, does anyone know if there's a setting that might be causing the issue, or perhaps the fact that its across tabs is an issue?

    Thanks

  8. #8
    Forum Moderator AliGW's Avatar
    Join Date
    08-10-2013
    Location
    Ipswich, England
    MS-Off Ver
    MS 365 Subscription Insider (Windows 11)
    Posts
    52,098

    Re: SUMIFS Multiple Criteria Same Column

    Unfortunately your post does not comply with Rule 2 of our Forum RULES. Do not post a question in the thread of another member -- start your own thread.

    If you feel an existing thread is particularly relevant to your need, provide a link to the other thread in your new thread.

    Old threads are often only monitored by the original participants. New threads not only open you up to all possible participants again, they typically get faster response, too.
    Ali


    Enthusiastic self-taught user of MS Excel who's always learning!

    Forum Rules (updated September 2018): please read them here.
    How to use the Power Query code you've been given: help here. More about the Power suite here.
    Don't forget to say "thank you" to those who have helped you in your thread. If you wish, you can also reward them by clicking on their reputation star bottom left.

+ Reply to Thread

Thread Information

Users Browsing this Thread

There are currently 1 users browsing this thread. (0 members and 1 guests)

Tags for this Thread

Bookmarks

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts

Search Engine Friendly URLs by vBSEO 3.6.0 RC 1