Countifs formula not working when referenced to another worksheet

I have attached a sample workbook which shows what I am trying to extract from sheet "Service Reminders 2014". In worksheet "Results" cells b11:e11 I am trying to extract the amount of vehicles with within age ranges provided that have a magic number attached which is pretty easy everything >0 is a proper magic number and also the amount of vehicles in each age range that have "Booked" associated within the range of "Service Reminders" Y2:AH5000, The formula works fine until I add the final criteria and then it give me a #VALUE! can anyone help with this i'm sure its something simple im doing wrong?
Thanks

Kepp your ranges in the same lenght
B11:

=COUNTIFS('Service Reminders 2014'!J:J,"<="&DATE(YEAR(TODAY())-0,MONTH(TODAY()),DAY(TODAY())),'Service Reminders 2014'!J:J,">="&DATE(YEAR(TODAY())-3,MONTH(TODAY()),DAY(TODAY())),'Service Reminders 2014'!E:E, ">=1")

You had problem here
=COUNTIFS('Service Reminders 2014'!J1:J4999,"<="&DATE(YEAR(TODAY())-0,MONTH(TODAY()),DAY(TODAY())),'Service Reminders 2014'!J1:J4999,">="&DATE(YEAR(TODAY())-3,MONTH(TODAY()),DAY(TODAY())),'Service Reminders 2014'!E:E, ">=1")

its because you are using a range for the dates and then a column for the >1 statement
change to

=COUNTIFS('Service Reminders 2014'!J1:J4999,"<="&DATE(YEAR(TODAY())-0,MONTH(TODAY()),DAY(TODAY())),'Service Reminders 2014'!J1:J4999,">="&DATE(YEAR(TODAY())-3,MONTH(TODAY()),DAY(TODAY())),'Service Reminders 2014'!E1:E4999, ">=1")

instead of
E:E

and it works

@etaf.
Tha would fail if you drag down...

True
thanks

=COUNTIFS('Service Reminders 2014'!$J$1:$J$4999,"<="&DATE(YEAR(TODAY())-0,MONTH(TODAY()),DAY(TODAY())),'Service Reminders 2014'!$J$1:$J$4999,">="&DATE(YEAR(TODAY())-3,MONTH(TODAY()),DAY(TODAY())),'Service Reminders 2014'!$E$1:$E$4999, ">=1")

Your last range covers more than 1column.

Attach your workbook.

Do you mind have a "helper" column? If not then put this formula in AJ2 copied down

=COUNTIF(Y2:AI2,"booked")

and then use this formula for between now and 3 years ago

=SUMIFS('Service Reminders 2014'!$AJ:$AJ,'Service Reminders 2014'!$J:$J,"<="&EDATE(TODAY(),0),'Service Reminders 2014'!$J:$J,">"&EDATE(TODAY(),-36))

Note that I used EDATE to get the dates, it's shorter. that counts months so 5 years ago is =EDATE(TODAY(),-60) etc.

Also you shouldn't have <= and >= in all the formulas otherwise you will be double counting on the boundary dates, so I used <= and >

The 302/304 discrepancy is because you have 2 rows (12 and 17) where there is a number >=1 in column E but no date in column J (just / / value), so those rows are included in the 304 but not included in any of your date ranges.

The 52/79 issue is because you haven't applied my suggested COUNTIF formula to every row in column AJ - presumably you added that formula while the data was filtered - remove all filters and apply again and you should get a closer match.

...also E12 formula is wrong, should be

=SUMIFS('Service Reminders 2014'!$AJ:$AJ,'Service Reminders 2014'!$J:$J,"<="&EDATE(TODAY(),-96))

Yes, I just edited my last reply - that formula should be

=SUMIFS('Service Reminders 2014'!$AJ:$AJ,'Service Reminders 2014'!$J:$J,"<="&EDATE(TODAY(),-96))