Count cells with specific date

I am trying to count how many times an account has been worked on each day and have not been able to find a formula.

Ive tried

=countif(B:B,"*11/3/2015*")

but get no results.

sample.JPG

I need to count how many cells contain
11/1/2015
11/2/2015
11/3/2015
11/4/2015
until current.

Thanks in advance for all the help

The only way I could get it to work was with a helper column. If you are open to that, then put this in cell D2 and drag down.
=ROUNDDOWN(B2,0)
Then do put this countif elsewhere...
=COUNTIF(D:D,42311) Where you use the numerical value of the date instead of the date.

You could also use a pivot table grouped on the date to give a count for each date.

	E	F
23	Row Labels	Count of Date
24	11/03/2015 12:22	13
25	12/03/2015 12:22	1
26	13/03/2015 12:22	3
27	Grand Total	17

If you want to see your data calculated, please upload a workbook with the data.

With the dates in D2 and down and the original data in columns A:C and the account in E2 the dates in column F enter this is G2 and fill down to give the count each day for the account named.

Formula:

=SUMPRODUCT( ($A$2:$A$100=$E$2)*(LEFT($B$2:$B$100,5)=LEFT(F2,5)))

This treats each date and time as a serial number and uses only the left 5 digits.
If you want to use the Date function:

Formula:

=SUMPRODUCT( ($A$2:$A$100=$E$2)*(DATE(YEAR($B$2:$B$100),MONTH($B$2:$B$100),DAY($B$2:$B$100))=DATE(YEAR(F2),MONTH(F2),DAY(F2))))

To just get the transactions for each day modify the formula to

Formula:

=SUMPRODUCT( ($A$2:$A$100>0)*(DATE(YEAR($B$2:$B$100),MONTH($B$2:$B$100),DAY($B$2:$B$100))=DATE(YEAR(F4),MONTH(F4),DAY(F4))))

Here is a setup similar to yours giving totals per day, totals per Admin, etc using Pivot Tables, Countifs, Sumproduct, and Sumproduct with Account #. (Formulae have been provided previously in other messages.)