How to separate numbers in a column to put in 3 different columns

[Brian.Aerojet]

Hi All,

I have added an attachment and explaining in the attachment of what I need.

It has confused me because of dates.

I need to take a column of numbers and put into 3 separate columns. It will follow a pattern

I put in data 3 times a day and then on Sunday only once.

I have 3 different columns that the 1st number will go in column J for that date, the 2nd number which is same Date will go in column L, and then the 3rd number

of same date will go in column N.

Once I get to Sunday, that number will go in column N also, right after the last number added on Saturday, after Sunday number is added, then it just repeats back to column J for the 1st number on Monday.

Thanks in advance
Brian

[Pete_UK]

So, do you want 3 rows for each date except Sundays, with the 3 numbers on separate rows as you have them now, or do you want just one row for each date?

Pete

[63falcondude]

Try this:

P8 =IFERROR(INDEX(C$8:C$36,MATCH(0,COUNTIF(P$7:P7,C$8:C$36),0)),"") Ctrl Shift Enter

J8 =IFERROR(INDEX(D$8:D$36,SMALL(IF(C$8:C$36=P8,ROW(C$8:C$36)-(ROW(C$8)-1)),COUNTIF(C$8:C$36,P8)-2)),"") Ctrl Shift Enter

L8 =IFERROR(INDEX(D$8:D$36,SMALL(IF(C$8:C$36=P8,ROW(C$8:C$36)-(ROW(C$8)-1)),2)),"") Ctrl Shift Enter

N8 =IFERROR(INDEX(D$8:D$36,SMALL(IF(C$8:C$36=P8,ROW(C$8:C$36)-(ROW(C$8)-1)),COUNTIF(C$8:C$36,P8))),"") Ctrl Shift Enter

Drag all formulas down until you get blanks.

[Brian.Aerojet]

Pete,
I would like to have them the way I have it set now
If I put them in a row for each date like you suggested it would interfere
With other formulas I have that correspond with this sheet

Thanks for your help
Brian

[Pete_UK]

Put the following formulae in the cells stated:

J8: =IF(WEEKDAY(C8)=1,"",IF(COUNTIF(C$8:C8,C8)=1,D8,""))

L8: =IF(WEEKDAY(C8)=1,"",IF(COUNTIF(C$8:C8,C8)=2,D8,""))

N8: =IF(WEEKDAY(C8)=1,D8,IF(COUNTIF(C$8:C8,C8)=3,D8,""))

then copy down as far as you need to.

Hope this helps.

Pete

[Brian.Aerojet]

Pete,

Thanks for your help with my issue

Worked like a charm

Thanks,

Brian

[Brian.Aerojet]

63falcondude,

Your formulas you give me worked good

So many ways to do just little things in excel.

Im so glad to have Experts and Guru's like you and Pete to help us on this forum

Thanks,
Brian

[63falcondude]

G;ad we could help. Thanks for the rep!