copying specific range of rows from every 720th step to new sheet columnwise

[iamrahul]

As per the excel file attached, you will observe that all data corresponding to pressure is enlisted in Column E from row number 12 and crank angle degrees in col D from same row number.
Now the data acquisition package stacks all pressure row wise for 80 cycles. now i need to transfer the pressure value from the 215th crank angle
(row 227) for each cycle which is 720 deg apart as you will see. Referring to the attached file Sheet 2 , i want that the 2nd row of each column of sheet 2 should give me the pressure value corresponding to 215 crank angle degree (column D) of each cycle 720 rows apart for the 80 cycles. I would then drag the new row values in sheet 2 to 500 rows to get the pressure values of interest in each cycle for the 80 cycles.

I will appreciate any help on this as all subsequent calculation depend vitally on this.

Obliged
Regards

[bebo021999]

Attach a sample workbook. Make sure there is just enough data to demonstrate your need. Include a BEFORE sheet and an AFTER sheet in the workbook if needed to show the process you're trying to complete or automate. Make sure your desired results are shown, mock them up manually if necessary.

Remember to desensitize the data.

Click on GO ADVANCED and then scroll down to Manage Attachments to open the upload window.

[iamrahul]

Please find the file attached.As you will observe that i have manually pasted the ranges of cylinder pressure from the first 2 cycles between row E227-E517 and that from E947-E1237 (highlighted) in sheet named ACTUAL.The starting points and ending row numbers are 720 rows apart correspondingly. Now i need to know as to how i can automate the procedure to get the pressure data between the same points for every cycle in columns in the DESIRED sheet.
Thank you for reaching out
Regards

Rahul

[Pete_UK]

You can put this formula in B2 of the Desired sheet:

=INDEX(INDIRECT("'ACTUAL'!E"&12+(COLUMNS($B:B)-1)*720&":E"&11+COLUMNS($B:B)*720),MATCH($A2,INDIRECT("'ACTUAL'!D"&12+(COLUMNS($B:B)-1)*720&":D"&11+COLUMNS($B:B)*720),0))

then copy across and down as required.

Hope this helps.

Pete

[Pete_UK]

Actually, here's a simplified version of that formula in B2:

=VLOOKUP($A2,INDIRECT("'ACTUAL'!D"&12+(COLUMNS($B:B)-1)*720&":E"&11+COLUMNS($B:B)*720),2,0)

Hope this helps.

Pete

[Pete_UK]

And here's one that doesn't use the volatile function INDIRECT:

=VLOOKUP($A2,INDEX(ACTUAL!$D:$D,12+(COLUMNS($B:B)-1)*720):INDEX(ACTUAL!$E:$E,11+COLUMNS($B:B)*720),2,0)

Hope this helps.

Pete

[iamrahul]

ALL OF THEM WORK.
THANK YOU. THANK YOU SO MUCH SIR. (YES I HAVE USED CAPS- BCS I WANNA SHOUT OUT)
ITS AMAZING .Its for kind souls like you that we exist.
REGARDS
(Pls clear ur pm message box-its not going-saying your inbox is full...i want to send u a personal message)