Counting formula is currently including blank cells and outputting " " because of this

Attaching files:

Use the Go Advanced option at the bottom of the page then scroll down to Manage Attachments as the "paperclip" method does not work on this forum.

Where is the workbook?

....

sorry I've just seen your attachment

Hi Again

in N15 to be copied across

=IFERROR(INDEX($B15:$L15,AGGREGATE(15,6,COLUMN($B:$L)-1/((COUNTIFS($B15:$L15,$B15:$L15,$B15:$L15,"<>0")=MAX(INDEX(COUNTIFS($B15:$L15,$B15:$L15,$B15:$L15,"<>0"),)))*(COUNTIF($M15:M15,$B15:$L15)=0)),1)),"")


Hope that helps

I amended your lower table to include formula blanks.

An alternative, array formula in H15, copied across and down:

=IFERROR(INDEX($B15:$L15,MODE(IF(B15:L15<>"",IF(COUNTIF($M15:M15,$B15:$L15)=0,MATCH($B15:$L15,$B15:$L15,0)+{0;0})))),"")

Array Formulae are a little different from ordinary formulae in that they MUST be confirmed in the FIRST CELL ONLY by pressing CTRL+SHIFT+ENTER to activate the array, not just ENTER. After that, the array can be dragged down as normal, to cover the desired range.

You will know the array is active when you see curly brackets { } - or "curly braces" for those of you in the USA, or "flower brackets" for those of you in India - appear around the outside of your formula. If you do not use CTRL+SHIFT+ENTER you will (almost always) get an error message or an incorrect answer. Press F2 on that cell and try again.

Don't type the curly brackets yourself - it won't work...

Hi All

I've udjusted one of the conditions of countifs (not <>0, but >A)

=IFERROR(INDEX($B15:$L15,AGGREGATE(15,6,COLUMN($B:$L)-1/((COUNTIFS($B15:$L15,$B15:$L15,$B15:$L15,">"&"A")=MAX(INDEX(COUNTIFS($B15:$L15,$B15:$L15,$B15:$L15,">"&"A"),)))*(COUNTIF($M15:M15,$B15:$L15)=0)),1)),"")

I hope it could be of some help

Hi. there is a $ error in my formula:

=IFERROR(INDEX($B15:$L15,MODE(IF($B15:$L15<>"",IF(COUNTIF($M15:M15,$B15:$L15)=0,MATCH($B15:$L15,$B15:$L15,0)+{0;0})))),"")

Hi All

in the attachment I'm exploiting column M as helper column in order to copy formulas toward right

In N15

=IFERROR(INDIRECT(TEXT(AGGREGATE(15,6,10^5*ROW($15:$23)+COLUMN($B:$K)/((COUNTIFS($B$15:$K$23,$B$15:$K$23,$B$15:$K$23,">"&"A")=MAX(INDEX(COUNTIFS($B$15:$K$23,$B$15:$K$23,$B$15:$K$23,">"&"A"),)))*(COUNTIF($M$15:M15,$B$15:$K$23)=0)),COLUMNS($A:A)),"R0C00000"),0),"")


Saluti