Wrapped SUMPRODUCT Function

[Darko_Giac]

Hi all,

I'm working with a table of fractions whose values I'm trying to sum using the sumproduct feature.

The "fractions" are being pulled from two different tables to track responses to a survey (how many we have/how many we need, so there's no real math going on in the actual formula, it's just referencing two tables and adding a "/" to create those "fractions")

However, I would like to sum the numbers on either side of the "/" to create a total row (workbook attached) using:

=SUMPRODUCT(--LEFT(A3:A7,1))&"/"&SUMPRODUCT(--RIGHT(A3:A7,2))

This works in cell A8, as the numbers on the left side of the "/" are all one digit in length, however, in cell B8, it sort of starts to misbehave, as there is a mix of double and single digit numbers on the left side of the "/", so it's throwing back an error because I've specified a length of 2 characters.

I'm wondering if there is a way to modify my existing formula so that it sums the numbers on the left side of the "/" regardless of length.

Any suggestions would be greatly appreciated!

Darko

[Pete_UK]

Use this in A8:

=SUMPRODUCT(--LEFT(A3:A7,FIND("/",A3:A7)-1))&"/"&SUMPRODUCT(--RIGHT(A3:A7,LEN(A3:A7)-FIND("/",A3:A7)))

then copy into B8.

Hope this helps.

Pete

[Darko_Giac]

Use this in A8:

=SUMPRODUCT(--LEFT(A3:A7,FIND("/",A3:A7)-1))&"/"&SUMPRODUCT(--RIGHT(A3:A7,LEN(A3:A7)-FIND("/",A3:A7)))

then copy into B8.

Hope this helps.

Pete

Thanks Pete, worked like a charm!

[Pete_UK]

You're welcome, and thanks for the rep, but you don't need to quote whole posts if you are responding directly - use the "Reply" button, rather than "Reply with Quote".

If that takes care of your original question, please take a moment to select Thread Tools from the menu above and to the right of your first post in this thread, and mark this thread as SOLVED.

Pete