Looking for a way to filter out duplicates and sort entries

Hello Everyone,

I will try to describe this as best as I can, but I find it difficult to explain.

I have a few columns of interest here:
Column B is Chemical Identifier Numbers
Column N is a category based on the use of them chemical (ranging 1-12 but excluding 8 and 11)
Column K is the percentage of use that is reported.

Right now I have written a formula that calculated the maximum value from Row K based on the numbers in row B and N.

=MAX(IF(B$2:B$87959=B2, IF(N$2:N$87959=N2, K$2:K$87959)))

and that output is located in Column O. Now I want to find a way to cut the excess and organize my sheet.

Here is an example of what it looks like now. You can see that for the material 123-45-6789, it has multiples in Column N but the values in column O are the same due to the formula I inputted above

_____B________N_____O

123-45-6789____4____0.5%
123-45-6789____4____0.5%
123-45-6789____3____0.1%
123-45-6789____4____0.5%
123-45-6789____1____0.09%
123-45-6789____4____0.5%
123-45-6789____2____0.35%
123-45-6789____2____0.35%
123-45-6789____4____0.5%
123-45-6789____5____0.41%
123-45-6789____5____0.41%
123-45-6789____5____0.41%
123-45-6789____6____0.29%
123-45-6789____4____0.5%
123-45-6789____3____0.1%
123-45-6789____5____0.41%
123-45-6789____4____0.5%
123-45-6789____6____0.29%

And this is what I am hoping to get.

All new columns here
123-45-6789____1____0.09%
123-45-6789____2____0.35%
123-45-6789____3____0.1%
123-45-6789____4____0.5%
123-45-6789____5____0.41%
123-45-6789____6____ 6 0.29%

Is there any way to do this?

if they were all side by side then it would be easy using the remove duplicates function. Is the data in between cols B and N necessary? If not you could still use the remove duplicates under the data tab. Have you considered that?

This proposal employs three helper columns which may be moved and or hidden for aesthetic purposes.
Note that the data starts on row 2.
Column P is populated using: =COUNTIFS(B3:B$38,B2,N3:N$38,N2)=0
Column R is populated using: =IFERROR(INDEX(B$1:B$37,AGGREGATE(15,6,ROW($1:$37)/($P$1:$P$37),ROW(1:1))),"")
Column S is populated using: =IF(R2="","",IF(R2<>R1,1,IF(OR(S1+1=8,S1+1=11),S1+2,S1+1)))
The filtered table (columns U:AI) is populated using: =IFERROR(INDEX(A$1:A$37,AGGREGATE(15,6,ROW($1:$37)/($B$1:$B$37=$R2)/($N$1:$N$37=$S2),1)),"")
If this doesn't resolve the issue please upload a sample spreadsheet that is representative of the actual data (without sensitive information) as well as the output that would be expected based on that data.
To upload a sample spreadsheet click on the GO ADVANCED button below the Quick Reply windown and then scroll down to Manage Attachments to open the upload window.
Let us know if you have any questions.