Nested If/And function based on multiple range conditions FAILING

I have returned again guys.. thank you for all the help you all have provided me.
The assistance helps because I use these tools at work, and usually I am submitting these inquiry's at work. It helps a lot.

Here is my problem:
Row S contains purchase cost.
Row T contains market value.
I am trying to populate the corresponding cells in column U based on certain constraints.
If T2<S2 = Underperformance
If the MV in T2 is between S2*1 - S2*1.25 = Minor move
If the MV in T2 is between S2*1.25 - S2*1.5 = Mid move
If the MV in T2 is between S2*1.5 - S2*1.75 = Major move
If the MV in T2 is between S2*1.75 - S2*2 = Drastic move

Every time I submit my formula, I get a FALSE result. I'm sure something is wrong with it.
See Below:

=IF(T2<S2,"Underperformance",
IF(AND(S2*1<T2<A2*1.25), "Minor Move",
IF(AND(S2*1.25<T2<S2*1.5),"Mid Move",
IF(AND(S2*1.5<T2<S2*1.75),"Major Move",
IF(AND(S2*1.75<T2<S2*2),"Drastic Move","")))))


Please assist.. thanks guys

Try it like this:

=IF(T2<S2,"Underperformance",
IF(T2<S2*1.25, "Minor Move",
IF(T2<S2*1.5,"Mid Move",
IF(T2<S2*1.75),"Major Move",
IF(T2<S2*2),"Drastic Move","")))))

Hope this helps.

Pete

Thank you very much Pete_UK. You're a genius.

That formula worked great, just removed the 2nd parenthesis before "Major Move".

Here is the final function:
=IF(S2=T2,"Unchanged",
IF(T2<S2,"Underperformance",
IF(T2<S2*1.25,"Minor Move",
IF(T2<S2*1.5,"Mid Move",
IF(T2<S2*1.75,"Major Move",
IF(T2<S2*2,"Drastic Move"," Other"))))))

Sorry, I missed that one when I deleted the AND parts from your original.

Note that if Excel gets past the first IF, then you don't need to test for that criterion anymore, and similarly, if it gets past the second IF, so your AND functions were redundant. Also, they were syntactically incorrect, as you can't write:

AND(S2<T2<S2*1.25)

You would have to write it as:

AND(S2<T2,T2<S2*1.25)

(no need for the *1).

Hope this helps.

Pete

Thanks for the rep. If that takes care of your original question, please take a moment to select Thread Tools from the menu above and to the right of your first post in this thread, and mark the thread as SOLVED.

Pete