# Index Match - first reply found repeated.

1. ## Index Match - first reply found repeated.

Still working on the "Wii Bowling League" spreadsheet, thanks to AVK, Pepe Le Mokko and GeoffW283 it is looking very good. Summing up the totals (high game, averages, etc.) and looking up the bowler's names is not working right. I used "=LARGE" to retrieve the Averages, then "=INDEX/MATCH" to retrieve the bowler's name. Index/Match repeats the first bowlers names found at that average. Here's the formula =INDEX(\$D\$2:\$D\$10,MATCH(D14,\$E\$2:\$E\$10,0))

High Averages.xlsx

2. ## Re: Index Match - first reply found repeated.

The attachment is not working - please try again.

INDEX MATCH is designed to return only the first match, so you will need something else for this.

Unfortunately the attachment icon doesn't work at the moment, so to attach an Excel file you have to do the following: just before posting, scroll down to Go Advanced and then scroll down to Manage Attachments. Now follow the instructions at the top of that screen.

3. ## Re: Index Match - first reply found repeated.

Was advised that my attachment was not working - here is that attachment.

4. ## Re: Index Match - first reply found repeated.

I used a helper column for this - F

F2=SUMPRODUCT((E2>E\$2:E\$10)/COUNTIF(E\$2:E\$10,E\$2:E\$10))+1
copied down.

D14=IFERROR(INDEX(\$E\$2:\$E\$10,MATCH(MAX(F2:F10)-ROWS(\$A\$1:A1)+1,\$F\$2:\$F\$10,0)),"")
E14=IFERROR(INDEX(\$D\$2:\$D\$10,MATCH(MAX(F2:F10)-ROWS(\$A\$1:A1)+1,\$F\$2:\$F\$10,0)),"")
copied down

5. ## Re: Index Match - first reply found repeated.

Thxs for your response - Ford, but I believe your response provides the next highest average with that bowler's name. What I'm trying to retrieve the second & third bowler's name (Pete & Polly) who also have a 193 average, instead of "HARRY" being repeated. Sorry for misleading you!

6. ## Re: Index Match - first reply found repeated.

Still using a helper column....
F2=E2-COUNTIF(\$E\$2:E2,E2)/1000
copied down
D14=IFERROR(INDEX(\$E\$2:\$E\$10,MATCH(LARGE(\$F\$2:\$F\$10,ROWS(\$A\$1:A1)),\$F\$2:\$F\$10,0)),"")
E14=INDEX(\$D\$2:\$D\$10,MATCH(LARGE(\$F\$2:\$F\$10,ROWS(\$A\$1:A1)),\$F\$2:\$F\$10,0))
both copied down

7. ## Re: Index Match - first reply found repeated.

Thxs Ford, that one worked great....pls mark this one - SOLVED. I couldn't figure out where to mark it!

Thank You, Walt

8. ## Re: Index Match - first reply found repeated.

Happy to help

The thread tools are located towards the top right of the screen, click tthe button to open a box so you can select SOLVED. I have done this 1 for you)

There are currently 1 users browsing this thread. (0 members and 1 guests)

#### Posting Permissions

• You may not post new threads
• You may not post replies
• You may not post attachments
• You may not edit your posts

Search Engine Friendly URLs by vBSEO 3.6.0 RC 1