Name and contact number get from main data

[shyampanda]

Hi,
I have a sheet where 4 column are there. I need the Employee name and contact number of the Locations where the designation is Branch Manager and in absent of Branch Manager then take Branch Credit Manager and their numbers. Thanks.

[JohnTopley]

Are you still on Excel 2007: if not, please update your profile as answers depend on knowing your Excel version.

[shyampanda]

Sorry Sir,
I have changed it to 2013. Request your help please.

[AliGW]

In G2:

=INDEX($A$2:$A$9,MATCH(1,($D$2:$D$9=$F2)*($B$2:$B$9=G$1),0))

In H2:

=INDEX($C$2:$C$9,MATCH(1,($D$2:$D$9=$F2)*($B$2:$B$9=G$1),0))

Copy down.

[Glenn Kennedy]

G2, copied down:

=IFERROR(INDEX($A$2:$A$9,IFERROR(MATCH(1,INDEX(($D$2:$D$9=F2)*($B$2:$B$9="Branch Manager"),0),0),MATCH(1,INDEX(($D$2:$D$9=F2)*($B$2:$B$9="Branch Credit Manager"),0),0))),"")

Similar for H2... see sheet.

[JohnTopley]

Another

=IFERROR(INDEX($A$2:$A$9,AGGREGATE(15,6,ROW($A$1:$A$100)/($D$2:$D$9=$F2)/(($B$2:$B$9="Branch Manager")+($B$2:$B$9="Branch Credit Manager")),1)),"")

=IFERROR(INDEX($C$2:$C$9,AGGREGATE(15,6,ROW($A$1:$A$100)/($D$2:$D$9=$F2)/(($B$2:$B$9="Branch Manager")+($B$2:$B$9="Branch Credit Manager")),1)),"")

[shyampanda]

Thanks you Madam and Mr. John and Glenn. I have tried the codes and all are working fine. Thanks again for your kind help.

[Glenn Kennedy]

You're welcome.

---

It would be very nice if you were to just click the Add Reputation button at the foot of any of the posts of members who helped you reach a solution.

Finally, if that takes care of your original question, please select "Thread Tools" from the menu link (just above the first post in the thread) and mark this thread as SOLVED.